替换反斜杠前缀

Question

伙计们，

我一直在试图让一个sed命令将在一个文件替换\'到'和\\"到\"单引号和双引号。我尝试了下面的使用sed，但我无法弄清楚如何分隔单引号和双引号。

$ cat temp 
\' 
\\" 

$ cat temp | sed 's#\\\\"#\\"#' | sed 's#\\'#'#' 
' 
" 

所需的输出是

' 
\" 

有人能指出我在做什么错。

注：我想在文件中这一变化适用于所有发生

Answer 1

AWK解决方案：

awk '{ gsub(/\\\047/,"\047",$0); gsub(/\\\\\042/,"\\\042",$0) }1' temp 

输出：

' 
\" 

Answer 2

测试与GNU sed 4.2.2 ，不确定可携带性
我修改输入样本显示命令更好的工作：

$ cat temp 
\' and \\' and \\\' 
\" and \\" and \\\" 

$ sed -E 's/\\([\x27"])/\1/g' temp 
' and \' and \\' 
" and \" and \\" 

• -E使用ERE，一些sed版本使用-r
• \\([\x27"])将匹配之后'或"\和单独的引号字符被捕获的
• \1捕获的组被用作替换
• g modi费里将取代所有这类事件排队

只改变\\"而不是\"

$ sed -E 's/\\\x27/\x27/g; s/\\\\"/\\"/g;' temp 
' and \' and \\' 
\" and \" and \\" 

Answer 3

任何发生这可能会为你工作（GNU SED）：

sed 's/\\\(\\['\''"]\)/\1/g' file 

或：

sed -r 's/\\(\\['\'"])/\1/g' file 

问题是单引号用于引用sed表达式，因此需要在shell中引用，因此\'。对单引号或双引号使用字符类允许替换使用后引用，从而简化替换的右侧。

Answer 4

您遇到的一个难题是您将表达式作为sed的命令行参数编写，因此需要为您的shell引用它。这是很容易，如果你在一个文件中写你的sed程序：

#!/bin/sed -f 

s/\\'/'/g 
s/\\\\"/\\"/g 

，需要在每个\翻一番，它们引用到s命令，但没有多余的引用，该外壳将需要。

示范：

$ cat 44649501.input 

\' 
\\" 

$ ./44649501.sed <44649501.input 

' 
\" 

Answer 5

对于任何sed的任何UNIX系统中：

$ sed 's/\\'\''/'\''/g; s/\\\\"/\\"/g' file 
' 
\" 

与GNU或OSX的sed的ERES与-E启用：

$ sed -E 's/\\('\''|\\")/\1/g' file 
' 
\"