VB6中的CheckTokenMembership - 在Windows 7和Windows 2008上崩溃FreeSID

Question

我正在使用CheckTokenMembership Windows API来检查用户是否是管理员。

下面的代码：

Option Explicit 

Private Const SECURITY_BUILTIN_DOMAIN_RID  As Long = &H20 
Private Const DOMAIN_ALIAS_RID_ADMINS   As Long = &H220 

Private Declare Function AllocateAndInitializeSid Lib "advapi32.dll" (pIdentifierAuthority As Any, ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Long, ByVal nSubAuthority1 As Long, ByVal nSubAuthority2 As Long, ByVal nSubAuthority3 As Long, ByVal nSubAuthority4 As Long, ByVal nSubAuthority5 As Long, ByVal nSubAuthority6 As Long, ByVal nSubAuthority7 As Long, lpPSid As Long) As Long 
Private Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As Long) 
Private Declare Function CheckTokenMembership Lib "advapi32.dll" (ByVal hToken As Long, ByVal pSidToCheck As Long, pbIsMember As Long) As Long 

Private Type SID_IDENTIFIER_AUTHORITY 
    Value(0 To 5)   As Byte 
End Type 

Private Function pvIsAdmin() As Boolean 
    Dim uAuthNt   As SID_IDENTIFIER_AUTHORITY 
    Dim pSidAdmins  As Long 
    Dim lResult   As Long 

    uAuthNt.Value(5) = 5 
    If AllocateAndInitializeSid(uAuthNt, 2, SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, 0, 0, 0, 0, 0, 0, pSidAdmins) <> 0 Then 
     If CheckTokenMembership(0, pSidAdmins, lResult) <> 0 Then 
      pvIsAdmin = (lResult <> 0) 
     End If 
     Call FreeSid(pSidAdmins) 
    End If 
End Function 

问题是，在Windows 7和Windows 2008 SP2，调用FreeSID导致应用程序崩溃。这次事故是间歇性的。

有没有人遇到过这个问题？

谢谢！

编辑：

我只是复查我的代码，我发现我宣布FreeSID这样：

Private Declare Sub FreeSid Lib "advapi32.dll" (pSid As Long) 

相比于上面的代码，这里的PSID参数没有被标记以ByVal。我添加了ByVal标志，问题不再存在。不知何故，我不相信这解决了这个问题。这可能解决了这个问题吗？

Answer 1

单独的pvIsAdmin在一个完全独立的模块和复制函数声明逐字从片段。在AllocateAndInitializeSid lpPSid是ByRef。在FreeSid参数是ByVal。