COUNTIF并打印计数的字符串

Question

需要您的VBA专业知识来完成以下任务。 我需要在一列上做一个“MACORS”城市标识，并打印数字旁边的每个城市。 我有这样的代码：

Public Sub CountLocation() 

Range("V2").Select 

Selection.End(xlDown).Select 
lastcell = ActiveCell.Address 

ActiveCell.Offset(2, 0).Value = "=countif(V2:" + lastcell + ", ""Zurich"")" 
ActiveCell.Offset(2, 1).Value = "Zurich" 
ActiveCell.Offset(3, 0).Value = "=countif(V2:" + lastcell + ", ""Armonk"")" 
ActiveCell.Offset(3, 1).Value = "Armonk" 
ActiveCell.Offset(4, 0).Value = "=countif(V2:" + lastcell + ", ""Hong Kong"")" 
ActiveCell.Offset(4, 1).Value = "Hong Kong" 
ActiveCell.Offset(5, 0).Value = "=countif(V2:" + lastcell + ", ""London"")" 
ActiveCell.Offset(5, 1).Value = "London" 
ActiveCell.Offset(6, 0).Value = "=countif(V2:" + lastcell + ", ""Madrid"")" 
ActiveCell.Offset(6, 1).Value = "Madrid" 

End Sub 

我的问题是我在一个片大约90“可能”城市，从其它片材而不同。 我上面的代码打印了一个不在特定工作表中的城市。

谢谢你的帮助

Answer 1

把城市放在一个数组中并循环该数组。此外，将计数范围作为一个范围。有一个如果测试大于0，所以不会写出城市，如果不存在。

一起：

Option Explicit 

Public Sub CountLocation() 

    Dim wb As Workbook 
    Dim ws As Worksheet 
    Dim countRange As Range 

    Set wb = ThisWorkbook 
    Set ws = wb.ActiveSheet 'Change as appropriate 

    Dim lastRow As Long 
    lastRow = ws.Range("V2").End(xlDown).Row 'Update: Extracted this into a variable 

    Set countRange = ws.Range(ws.Cells(2, "V"), ws.Cells(lastRow, "V")) 

    Dim Cities() 
    Cities = Array("Zurich", "Armonk", "Hong Kong", "London", "Madrid") 

    Dim city As Long 
    Dim counter As Long 
    Dim startRange As Range 

    Set startRange = ws.Cells(lastRow, "V").Offset(2, 0) 

    counter = 2 

    For city = LBound(Cities) To UBound(Cities) 
     If Application.WorksheetFunction.CountIf(countRange, Cities(city)) > 0 Then 
     startRange.Offset(counter, 0) = Application.WorksheetFunction.CountIf(countRange, Cities(city)) 
     startRange.Offset(counter, 1) = Cities(city) 
     counter = counter + 1 
     End If 

    Next city 

End Sub 

注意事项的各个部分：

下在V列从V2开始空白单元格之前得到最后使用一行。如果在上次使用的单元格之前有空单元格，则会得到错误的最后一行。

lastRow = ws.Range("V2").End(xlDown).Row, "V") 

然后设置的范围为V2算到最后使用的排五：

Set countRange = ws.Range(ws.Cells(2, "V"),ws.Cells(lastRow, "V")) 

定义在那里你会开始写出来的结果：

Set startRange = ws.Cells(lastRow, "V").Offset(2, 0) 

在计数范围内循环计算特定城市发生的城市阵列：

Application.WorksheetFunction.CountIf(countRange, Cities(city)) 

将它包装在IF语句中以查看count是否大于0。

If Application.WorksheetFunction.CountIf(countRange, Cities(city)) > 0 

写出来的片从第一粘贴位置由一个行每次使用计数器变量抵消：

startRange.Offset(counter, 0) = Application.WorksheetFunction.CountIf(countRange, Cities(city)) 
startRange.Offset(counter, 1) = Cities(city)