XSLT +解析字符串

Question

我想下面的消息字符串解析：

"Row 1> testdata1 |Row 5> testdata2 |Row 7> testdata3" 

成HTML表格格式：

<tr> 
    <td>Row 1</td><td>testdata1</td> 
    <td>Row 5</td><td>testdata2</td> 
    <td>Row 7</td><td>testdata3</td> 
</td> 

这里是我当前的尝试：

<xsl:template match="Row"> 
    <tbody><xsl:apply-templates/></tbody> 
</xsl:template> 

<xsl:template match="col1" > 
    <xsl:call-template name="parseStr" > 
    <xsl:with-param name="txt" select="text()" /> 
    </xsl:call-template> 
</xsl:template> 

<xsl:template name="parseStr"> 
    <xsl:param name="txt" select="''" /> 
    <tr><xsl:choose> 
     <xsl:when test="contains($txt, '>')" > 
     <td><xsl:value-of select="substring-before($txt, '>')" /></td><td><xsl:value-of select="substring-after($txt, '>')" /></td> 
     </xsl:when> 

     <xsl:otherwise> 
     <td><xsl:value-of select="$txt" /></td> 
     </xsl:otherwise> 
    </xsl:choose></tr> 

    <xsl:variable name="leftStr" select="substring-after($txt, '|')" /> 
    <xsl:if test="string-length($leftStr)>1" > 
     <xsl:call-template name="parseStr" > 
     <xsl:with-param name="txt" select="$leftStr" /> 
     </xsl:call-template> 
    </xsl:if> 

</xsl:template> 

这个XSLT提供了正确的表结构。在初始>中断后，我很难分开testdata字符串。

输出：

<tr> 
    <td>Row 1</td><td>testdata1 |Row 5> testdata2 |Row 7> testdata3</td> 
    <td>Row 5</td><td>testdata2 |Row 7> testdata3</td> 
    <td>Row 7</td><td>testdata 3</td> 
</tr> 

UPDATE 我已经想通了如何抓住文本其间的字符串。我添加了以下内容：

<td><xsl:value-of select="substring-before($txt, '>')" /></td><td><xsl:value-of select="substring-after(substring-before($txt, '|'), '>')" /></td> 

但是，我错过了最后解析的消息“testdata3”。

此外，这里是原始的XML：

<Rowsets> 
    <Rowset> 
    <Row> 
     <col1>Row 1> testdata1 |Row 5> testdata2 |Row 7> testdata3</col1> 
    </Row> 
    </Rowset> 
</Rowsets> 

更新2：

成功！我想出了解决办法。然而，也有可能是一个更容易/清洁的方式......这是我的解决方案，如果你有兴趣:-)

<xsl:template name="parseStr"> 
    <xsl:param name="txt" select="''" /> 
    <tr><xsl:choose> 
     <xsl:when test="contains($txt, '|')" > 
     <td><xsl:value-of select="substring-before($txt, '>')" /></td><td><xsl:value-of select="substring-after(substring-before($txt, '|'), '>')"/></td> 
     </xsl:when> 
     <xsl:otherwise> 
     <td><xsl:value-of select="substring-before($txt, '>')" /></td><td><xsl:value-of select="substring-after($txt, '>')" /></td> 
     </xsl:otherwise> 
    </xsl:choose></tr> 

    <xsl:variable name="leftStr" select="substring-after($txt, '|')" /> 
    <xsl:if test="string-length($leftStr)>1" > 
    <xsl:call-template name="parseStr" > 
     <xsl:with-param name="txt" select="$leftStr" /> 
    </xsl:call-template> 
    </xsl:if> 

</xsl:template> 

Answer 1

一本XSLT 1.0转换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/*"> 
    <tr> 
    <xsl:apply-templates/> 
    </tr> 
</xsl:template> 

<xsl:template match="text()" name="makeTDs"> 
    <xsl:param name="pStr" select="."/> 

    <xsl:if test="string($pStr)"> 
    <xsl:variable name="vText" select="concat($pStr, ' |')"/> 
    <xsl:variable name="vPair" select= 
    "substring-before($vText, ' |')"/> 
    <td> 
    <xsl:value-of select="substring-before($vPair, '> ')"/> 
    </td> 
    <td> 
    <xsl:value-of select="substring-after($vPair, '> ')"/> 
    </td> 

    <xsl:call-template name="makeTDs"> 
    <xsl:with-param name="pStr" select= 
     "substring-after($pStr, ' |')"/> 
    </xsl:call-template> 
    </xsl:if> 
</xsl:template> 
</xsl:stylesheet> 

当应用于这个XML文档：

<t>Row 1> testdata1 |Row 5> testdata2 |Row 7> testdata3</t> 

产生想要的，正确的结果：

<tr> 
    <td>Row 1</td> 
    <td>testdata1</td> 
    <td>Row 5</td> 
    <td>testdata2</td> 
    <td>Row 7</td> 
    <td>testdata3</td> 
</tr> 

---

II。 XSLT 2。0溶液：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/*"> 
    <tr> 
    <xsl:for-each select="tokenize(., ' \|')"> 
    <xsl:for-each select="tokenize(., '> ')"> 
     <td><xsl:sequence select="."/></td> 
    </xsl:for-each> 
    </xsl:for-each> 
    </tr> 
</xsl:template> 
</xsl:stylesheet> 

这种转变，当在相同的XML文档应用（见上文）产生相同的正确的结果：

<tr> 
    <td>Row 1</td> 
    <td>testdata1</td> 
    <td>Row 5</td> 
    <td>testdata2</td> 
    <td>Row 7</td> 
    <td>testdata3</td> 
</tr> 

Answer 2

我奋力一点点了解您的输入XML - 没有它被搞的一团糟编辑。它当然看起来不是格式正确的XML，我没有看到任何<Row>或<Col>元素。

然而，这一行看起来错误：

<xsl:param name="txt" select="''" /> 

我认为这应该只是阅读

<xsl:param name="txt">