如何获取星期六的日期（或任何其他星期几的日期） - SQL Server

Question

如何获取星期六的日期。我今天和我约会。

GETDATE() 

如何做到这一点。

例如，今天是08-08-2011

我想为08-13-2011

Answer 1

这是，如果你这样称呼它，将返回下周六功能：

SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 6) 

“6” 来自the list of possible values可以为DATEFIRST设置。

您可以通过相应地更改第二个参数来获得任何其他星期几。

这是函数：

IF OBJECT_ID('dbo.fn_Get_NextWeekDay') IS NOT NULL 
    DROP FUNCTION dbo.fn_Get_NextWeekDay 
GO 
CREATE FUNCTION dbo.fn_Get_NextWeekDay(
    @aDate DATETIME 
    , @dayofweek  INT 
    /* 
     @dw - day of the week 
     1 - Monday 
     2 - Tuesday 
     3 - Wednesday 
     4 - Thursday 
     5 - Friday 
     6 - Saturday 
     7 - Sunday 
    */ 
) 
RETURNS DATETIME 
AS 
/* 
    SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 6) 
    SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 1) 
*/ 
BEGIN 
    RETURN 
     DATEADD(day 
     , (@dayofweek + 8 - DATEPART(dw, @aDate) - @@DATEFIRST) % 7 
     , @aDate 
    ) 
END 
GO 

[编辑] 这可能是另一种解决办法。这应该在任何语言工作：

IF OBJECT_ID('dbo.fn_NextWeekDay') IS NOT NULL 
    DROP FUNCTION dbo.fn_NextWeekDay 
GO 
CREATE FUNCTION dbo.fn_NextWeekDay(
    @aDate  DATE 
    , @dayofweek NVARCHAR(30) 
) 
RETURNS DATE 
AS 
/* 
    SELECT dbo.fn_NextWeekDay('2016-12-14', 'fri') 
    SELECT dbo.fn_NextWeekDay('2016-03-15', 'mon') 
*/ 
BEGIN 
    DECLARE @dx INT = 6 
    WHILE UPPER(DATENAME(weekday,@aDate)) NOT LIKE UPPER(@dayofweek) + '%' 
    BEGIN 

    SET @aDate = DATEADD(day,1,@aDate) 

    SET @dx=@dx-1 
    if @dx < 0 
    BEGIN 
     SET @aDate = NULL 
     BREAK 
    END 
    END 

    RETURN @aDate 

END 
GO 

Answer 2

使用DATEPART输出到取得今天的一周中的一天，并添加差一周到今天的日期所需天。

Answer 3

签出SQL DATEADD函数。

DATEADD (Transact-SQL)

，您可以用DATEPART函数一起使用这个返回正确的日期。

DATEPART (Transact-SQL)

Answer 4

DECLARE @Today date = 'TODAYS-DATE'; 
DECLARE @TodayNumber int = DATEPART(dw, @Today) -- Get the day number 
DECLARE @Saturday date = DATEADD(DAY, (6-@TodayNumber)%7, @Today) 
-- Add the number of days between today and saturday (the 6th day), modulus 7 to stop you adding negative days 

希望帮助！

Answer 5

试试这个：

SET DATEFIRST 7 
DECLARE @d DATETIME 
SET @d = '2011-08-08' --GETDATE() 

SELECT NEXT_SAT = DATEADD(day, (7 + @@DATEFIRST - DATEPART(dw, @d)) % 7, @d) 

Answer 6

使用日历表（表，每个日期一行）：

SELECT MIN(DateValue) DateValue 
FROM Calendar 
WHERE DateValue >= CURRENT_TIMESTAMP 
AND DayOfWeek = 'Saturday';