VBS中的日期格式

Question

我想在我的vbscript中获得完整格式的日期。例如，我把
DateParam = FormatDateTime(Date()-1, 2)

但它返回

3/8/2012
我需要的功能恢复
03/08/2012代替。

有谁知道如何解决这个问题？

Answer 1

ThisDate = Date() 

MyDate = Right("0" & CStr(Month(ThisDate)), 2) & "/" & _ 
     Right("0" & CStr(Day(ThisDate)), 2) & "/" & CStr(Year(ThisDate)) 

Answer 2

FormatDateTime函数是没用的，因为它取决于用户的具体和全局区域设置。

对于日期来说，最好的（最少的努力获得最大的收益）解决方案 - 攻击.NET - 是有缺陷的;再次因为依赖区域设置。

如果你想/需要推出你自己的功能，从fmtDate（）开始。

Dim g_oSB : Set g_oSB = CreateObject("System.Text.StringBuilder") 

Function sprintf(sFmt, aData) 
    g_oSB.AppendFormat_4 sFmt, (aData) 
    sprintf = g_oSB.ToString() 
    g_oSB.Length = 0 
End Function 

Function fmtDate(dtX) 
    fmtDate = Join(Array(   _ 
     Right(100 + Month(dtX), 2) _ 
    , Right(100 + Day(dtX), 2) _ 
    ,    Year(dtX)  _ 
), "/") 
End Function 

Dim dtYesterday : dtYesterday = Date() - 1 
WScript.Echo "Yesterday:", dtYesterday, GetLocale() 
WScript.Echo "sprintf (silly) =>", sprintf("{0:MM/dd/yyyy}", Array(dtYesterday)) 
WScript.Echo "sprintf (clumsy) =>", sprintf("{0:MM}/{0:dd}/{0:yyyy}", Array(dtYesterday)) 
WScript.Echo "fmtDate   =>", fmtDate(dtYesterday) 

输出：

Yesterday: 08.03.2012 1033 
sprintf (silly) => 03.08.2012 
sprintf (clumsy) => 03/08/2012 
fmtDate   => 03/08/2012 

关于第二个想法：

逃离 “/” 有助于使的sprintf（）可用：

WScript.Echo "sprintf (silly me) =>", sprintf("{0:MM\/dd\/yyyy}", Array(dtYesterday)) 

输出：

sprintf (silly me) => 03/08/2012 

所以不要打扰fmt *功能，但使用.NET格式。