两阶段处理：不要输出阶段1 XSLT 2.0处理中的空标记

Question

我有一些复杂的XSLT 2.0转换。我试图找出是否有通用的方法来确保不输出空标签。所以......从概念上讲，递归处理的最后阶段是删除所有空标签。我知道这可以通过一个单独的XSLT来完成，它不做任何事情，但是会过滤掉空标签，但我需要将它们全部封装在一起。

Answer 1

此XSLT 2.0变换示出了如何多遍（在这个例子2通）处理可以做到：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*" mode="#all"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*" mode="#current"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/"> 
    <xsl:variable name="vPass1"> 
    <xsl:apply-templates/> 
    </xsl:variable> 

    <xsl:apply-templates select="$vPass1/*" mode="non-empty"/> 
</xsl:template> 

<xsl:template match="text()[xs:integer(.) mod 2 eq 0]"/> 

<xsl:template match="*[not(node())]" mode="non-empty"/> 
</xsl:stylesheet> 

当此XML文档上施加：

<nums> 
    <num>01</num> 
    <num>02</num> 
    <num>03</num> 
    <num>04</num> 
    <num>05</num> 
    <num>06</num> 
    <num>07</num> 
    <num>08</num> 
    <num>09</num> 
    <num>10</num> 
</nums> 

它在第一遍中创建结果文档（在$vPass1变量中捕获该文档），其中所有内容均匀的<num>元素r被删除了内容并且是空的。然后，在第二遍中，以特定模式应用，所有空元素都被删除。

转换的结果是：

<nums> 
    <num>01</num> 
    <num>03</num> 
    <num>05</num> 
    <num>07</num> 
    <num>09</num> 
</nums> 

请注意使用模式，而特殊模式#all和#current。

更新： OP现在希望在评论中删除“递归”“没有非空后裔的所有节点”。

这可以使用没有显式递归更简单地实现。只要改变：

<xsl:template match="*[not(node())]" mode="non-empty"/> 

到：

<xsl:template match="*[not(descendant::text())]" mode="non-empty"/>