在emacs中向上和向下移动行/区域

Question

在emacs中向上或向下移动所选区域或行（如果没有选择），最简单的方法是什么？我正在寻找与eclipse中相同的功能（以M-up，M-down为界）。

Answer 1

一条线可以使用transpose-lines绑定到C-x C-t。不过不知道地区。

我找到了this elisp片段，它可以做你想做的事情，除非你需要改变绑定。

(defun move-text-internal (arg) 
    (cond 
    ((and mark-active transient-mark-mode) 
    (if (> (point) (mark)) 
      (exchange-point-and-mark)) 
    (let ((column (current-column)) 
       (text (delete-and-extract-region (point) (mark)))) 
     (forward-line arg) 
     (move-to-column column t) 
     (set-mark (point)) 
     (insert text) 
     (exchange-point-and-mark) 
     (setq deactivate-mark nil))) 
    (t 
    (beginning-of-line) 
    (when (or (> arg 0) (not (bobp))) 
     (forward-line) 
     (when (or (< arg 0) (not (eobp))) 
      (transpose-lines arg)) 
     (forward-line -1))))) 

(defun move-text-down (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines down." 
    (interactive "*p") 
    (move-text-internal arg)) 

(defun move-text-up (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines up." 
    (interactive "*p") 
    (move-text-internal (- arg))) 

(global-set-key [\M-\S-up] 'move-text-up) 
(global-set-key [\M-\S-down] 'move-text-down) 

Answer 2

没有内置的。您可以使用转置线（C-x C-t），但不能反复使用。看看http://www.schuerig.de/michael/blog/index.php/2009/01/16/line-movement-for-emacs/上的功能。

它也应该很容易适应地区。

Answer 3

transpose-paragraph功能可以帮助你。

您可能还想看看Emacs手册中的转置部分。 本质：

C-t 
Transpose two characters (transpose-chars). 
M-t 
Transpose two words (transpose-words). 
C-M-t 
Transpose two balanced expressions (transpose-sexps). 
C-x C-t 
Transpose two lines (transpose-lines). 

Answer 4

我已经写了几个互动功能动线向上/向下：

;; move line up 
(defun move-line-up() 
    (interactive) 
    (transpose-lines 1) 
    (previous-line 2)) 

(global-set-key [(control shift up)] 'move-line-up) 

;; move line down 
(defun move-line-down() 
    (interactive) 
    (next-line 1) 
    (transpose-lines 1) 
    (previous-line 1)) 

(global-set-key [(control shift down)] 'move-line-down) 

的绑定键是IntelliJ IDEA的风格，但你可以使用任何你想要的。我也许应该实现一些在各个地区运作的功能。

Answer 5

更新：安装Marmalade的move-text包或MELPA获取以下代码。

这是我使用，这两个地区和各条线的工作原理：

(defun move-text-internal (arg) 
    (cond 
    ((and mark-active transient-mark-mode) 
    (if (> (point) (mark)) 
     (exchange-point-and-mark)) 
    (let ((column (current-column)) 
      (text (delete-and-extract-region (point) (mark)))) 
     (forward-line arg) 
     (move-to-column column t) 
     (set-mark (point)) 
     (insert text) 
     (exchange-point-and-mark) 
     (setq deactivate-mark nil))) 
    (t 
    (let ((column (current-column))) 
     (beginning-of-line) 
     (when (or (> arg 0) (not (bobp))) 
     (forward-line) 
     (when (or (< arg 0) (not (eobp))) 
      (transpose-lines arg) 
      (when (and (eval-when-compile 
         '(and (>= emacs-major-version 24) 
          (>= emacs-minor-version 3))) 
        (< arg 0)) 
      (forward-line -1))) 
     (forward-line -1)) 
     (move-to-column column t))))) 

(defun move-text-down (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines down." 
    (interactive "*p") 
    (move-text-internal arg)) 

(defun move-text-up (arg) 
    "Move region (transient-mark-mode active) or current line 
    arg lines up." 
    (interactive "*p") 
    (move-text-internal (- arg))) 


(global-set-key [M-S-up] 'move-text-up) 
(global-set-key [M-S-down] 'move-text-down) 

Answer 6

有一个在Emacs的维基只为这一个条目：

http://www.emacswiki.org/emacs/MoveLine

对于运动区域：

http://www.emacswiki.org/emacs/MoveRegion

Answer 7

这里是我的代码片段来移动当前行或活动区域跨越的行。它尊重光标位置和突出显示的区域。当该区域不以线边界开始/结束时，它不会断线。 （它是由偏食的启发，我找到了日食的方式比“转线”更方便。）

;; move the line(s) spanned by the active region up/down (line transposing) 
;; {{{ 
(defun move-lines (n) 
    (let ((beg) (end) (keep)) 
    (if mark-active 
     (save-excursion 
      (setq keep t) 
      (setq beg (region-beginning) 
       end (region-end)) 
      (goto-char beg) 
      (setq beg (line-beginning-position)) 
      (goto-char end) 
      (setq end (line-beginning-position 2))) 
     (setq beg (line-beginning-position) 
      end (line-beginning-position 2))) 
    (let ((offset (if (and (mark t) 
          (and (>= (mark t) beg) 
           (< (mark t) end))) 
         (- (point) (mark t)))) 
      (rewind (- end (point)))) 
     (goto-char (if (< n 0) beg end)) 
     (forward-line n) 
     (insert (delete-and-extract-region beg end)) 
     (backward-char rewind) 
     (if offset (set-mark (- (point) offset)))) 
    (if keep 
     (setq mark-active t 
       deactivate-mark nil)))) 

(defun move-lines-up (n) 
    "move the line(s) spanned by the active region up by N lines." 
    (interactive "*p") 
    (move-lines (- (or n 1)))) 

(defun move-lines-down (n) 
    "move the line(s) spanned by the active region down by N lines." 
    (interactive "*p") 
    (move-lines (or n 1))) 

Answer 8

你应该尝试drag-stuff！

它的工作原理完全一样日食Alt键 + 向上/下单线条，以及符合所选区域的线！

此外，它可以让你与Alt键 + 左/右
这正是你要寻找移动的话！它甚至可以从ELPA repos！

其他解决方案从来没有为我工作。其中一些是越野车（在改变顺序的同时换位线，wtf？），其中一些正在移动恰好选定的区域，而未选定部分的线位于其位置上。但是drag-stuff和eclipse完全一样！

甚至更​​多！您可以尝试选择一个区域并使用Alt + Left/Right！这会将所选区域左移或右移一个字符。惊人！

要启用全局简单地运行这样的：

(drag-stuff-global-mode) 

Answer 9

我用的是智能换档组件（在Melpa）这一点。默认情况下，它重新绑定C-C <arrow>以移动一条线或区域。它按主模式特定的量水平移动（例如c-basic-offset或python-indent-offset）。也在地区工作。

;; binds C-C <arrows> 
(when (require 'smart-shift nil 'noerror) 
    (global-smart-shift-mode 1))