从一个数组到另一个数组传递随机值没有重复

Question

我有一个数组（说'origA'），其中包含20个值和另一个数组（说“itemA”只有1值，我需要推任何10随机值“ORIGA”到“意达”的，但我不能把它已经被推到“意达”相同的值。

我们怎样才能做到这一点？

Answer 1

// Define how many random numbers are required. 
const REQUIRED:int = 10; 

// Loop until either the original array runs out of numbers, 
// or the destination array reaches the required length. 
while(origA.length > 0 && itemA.length < REQUIRED) 
{ 
    // Decide on a random index and pull the value from there. 
    var i:int = Math.random() * origA.length; 
    var r:Number = origA[i]; 

    // Add the value to the destination array if it does not exist yet. 
    if(itemA.indexOf(r) == -1) 
    { 
     itemA.push(r); 
    } 

    // Remove the value we looked at this iteration. 
    origA.splice(i, 1); 
} 

Answer 2

您可以创建一个副本origA并从中删除您添加到itemA的项目：

非优化的版本：

var origA:Array = [1, 2, 3, 4, 5, 6, 7]; 
var itemA:Array = [0]; 

var copyA:Array = origA.concat(); 
var N:int = 10; 
var n:int = Math.min(N, copyA.length); 

for (var i:int = 0; i < n; i++) { 
    // Get random value 
    var index:int = Math.floor(Math.random() * copyA.length); 
    var value:int = copyA[index]; 
    // Remove the selected value from copyA 
    copyA.splice(index, 1); 
    // Add the selected value to itemA 
    itemA.push(value); 
} 

trace(itemA); 
//0,1,7,2,6,4,3,5 

优化的版本（以length没有电话，indexOf，splice或push环内）：

var origA:Array = [1, 2, 3, 4, 5, 6, 7]; 
var itemA:Array = [0]; 

var copyA:Array = origA.concat(); 
var copyALength:int = copyA.length; 
var itemALength:int = itemA.length; 
var N:int = 10; 
var n:int = Math.min(N, copyALength); 
for (var i:int = 0; i < n; i++) { 
    // Get random value 
    var index:int = Math.floor(Math.random() * copyALength); 
    var value:int = copyA[index]; 
    // Remove the selected value from copyA 
    copyA[index] = copyA[--copyALength]; 
    // Add the selected value to itemA 
    itemA[itemALength++] = value; 
} 

trace(itemA); 
//0,2,5,7,4,1,3,6 

---

EDIT1：如果你原来的数组只有几个项目，在其他答案中使用我的第一个版本或任何其他解决方案。但是，如果它可能有数千个项目或更多，那么我建议您使用我的优化版本。

---

编辑：2这里是从含有1,000,000项的数组复制1,000随机选择的项目所花费的时间：

• 所有其他版本：2000ms
• 优化版本：12ms
• 无需克隆原始阵列的优化版本：1ms

Answer 3

这是一个真正的短。从原来的数组中删除随机项目，直到你达到MAX，然后CONCAT到目标磁盘阵列：

const MAX:int = 10; 
var orig:Array = [0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20]; 
var target:Array = []; 
var tmp:Array = []; 
var i : int = -1; 
var len : int = orig.length; 
while (++i < MAX && len > 0) { 
    var index:int = int(Math.random()*len); 
    tmp[i] = orig[index]; 
    orig[index] = orig[--len]; 
} 
target = target.concat(tmp); 

编辑删除项目的

采纳@ SCH的方式。这是他应该接受的答案。我只保留了这个while循环。