awk命令为十六进制转换为符号十进制

我具有由3列与十六进制数的（值是可变的，这些仅作为一个例子）的文本文件：awk命令为十六进制转换为符号十进制

X  Y  Z 
0a0a 0b0b 0c0c 
0a0a 0b0b 0c0c 
0a0a 0b0b 0c0c 
0a0a 0b0b 0c0c

我想这些数字转换有符号的十进制和打印他们在相同的结构，他们都在，所以我所做的：

awk '{x="0x"$1; 
     y="0x"$2; 
     z="0x"$3; 
     printf ("%d %d %d" x,y,z);}' input_file.txt > output_file.txt

，我得到作为输出仅包括无符号值的列表。

来源

2016-09-23 NitrogenAir

由于样本输入中的十六进制数字全部以零字节开始，因此通常会将其视为正数。他们中的任何一个应该被视为否定的？ – John1024

你可以发布你的预期输出吗？并给出的awk片段有语法问题 – Sundeep

awk不支持它，尝试使用像这里描述的一个黑客http://stackoverflow.com/questions/37551094/awk-convert-big-unsigned-int-to-signed- int-binary来证明awk无法使用int2hex awk'{printf'％x/n“，-1}'它会告诉你ffffffffffffffff尝试向后awk'{printf”％d/n，0xffffffffffffffff“}'你会得到一个巨大的正整数。这与shell printf命令一样。预计产量为 –

您可以使用awk功能，使一个Conversion from Two's Complement：

function hex2int(hexstr, nbits) 
{ 
    max = 2^nbits 
    med = max/2 

    num = strtonum("0x" hexstr) 

    return ((num < med) ? num : ((num > med) ? num - max : -med)) 
}

4bit转换的例子：

print hex2int("7", 4) # +7 
print hex2int("2", 4) # +2 
print hex2int("1", 4) # +1 
print hex2int("0", 4) # 0 
print hex2int("f", 4) # -1 
print hex2int("d", 4) # -3 
print hex2int("9", 4) # -7 
print hex2int("8", 4) # -8

8bit转换的例子：

print hex2int("7f", 8) # +127 
print hex2int("40", 8) # +64 
print hex2int("01", 8) # +1 
print hex2int("00", 8) # 0 
print hex2int("ff", 8) # -1 
print hex2int("40", 8) # -64 
print hex2int("81", 8) # -127 
print hex2int("80", 8) # -128

把所有在一起使用16bit转换：

#!/bin/awk 

function hex2int(hex) 
{ 
    num = strtonum("0x" hex) 

    return ((num < med) ? num : ((num > med) ? num - max : -med)) 
} 

BEGIN { 
    nbits = 16 
    max = 2^nbits 
    med = max/2 
} 

{ 
    for(i = 1; i <= NF; i++) 
    { 
     if(NR == 1) 
     { 
      printf "%s%s", $i, OFS 
     } 
     else 
     { 
      printf "%d%s", hex2int($i), OFS 
     } 
    } 

    printf "%s", ORS 
} 

# eof #

输入文件：

X  Y  Z 
0a0a 0b0b 0c0c 
abcd ef01 1234 
ffff fafa baba 
12ab abca 4321

测试：

$ awk -f script.awk -- input.txt

输出：

X Y Z 
2570 2827 3084 
-21555 -4351 4660 
-1 -1286 -17734 
4779 -21558 17185

参考：https://en.wikipedia.org/wiki/Two's_complement

希望它有帮助！

来源

2016-09-23 14:19:58 Lacobus

awk命令为十六进制转换为符号十进制

回答

相关问题