转换日期时间格式之间使用Perl

Question

我们目前正在使用第三方API，它提供了以下格式的日期时间：

Sat Mar 06 09:00:00 ICST 2010 
Fri Feb 19 19:30:00 JDT 2010 
Fri Feb 19 19:30:00 PST 2010 

但是，我们要在MySQL这些datetime对象存储在一个标准的日期时间字段，需要的格式如下：

YYYY-MM-DD HH:MM:SS 

现在，让我们用下面的代码被报告某些时区，如KDT，JDT和ICST错误：

use Date::Manip; 
use DateTime; 
use DateTime::Format::DateManip; 

my $date = ParseDate($time); 
$date = DateTime::Format::DateManip->parse_datetime($date); 
eval{ $time = $date->strftime("%Y-%m-%d %H:%M:%S"); }; 

你能推荐一个更好的实现上面的Perl代码来将API中的日期时间对象转换为正确的格式和时间在我们的服务器上插入MySQL日期时间字段吗？

在此先感谢您的帮助&意见！

Answer 1

商店的时间内在GMT。在GMT进行所有操作。然后在最后一刻，就像您即将向用户显示结果一样，，然后将转换为用户的本地时间。

我推荐使用Date::Parse，但是你必须增加它的时区偏移量，因为它目前没有印度支那夏令时和日本夏令时。

#! /usr/bin/perl 

use warnings; 
use strict; 

use Date::Format; 
use Date::Parse; 

# add timezone offsets 
$Time::Zone::Zone{icst} = +7*3600; 
$Time::Zone::Zone{jdt} = +9*3600; 

while (<DATA>) { 
    chomp; 
    warn("$0: failed conversion for $_\n"), next 
    unless defined(my $time_t = str2time $_); 

    my @t = gmtime($time_t); 
    print $_, " => ", strftime("%Y-%m-%d %H:%M:%S", @t), "\n"; 
} 

__DATA__ 
Sat Mar 06 09:00:00 ICST 2010 
Fri Feb 19 19:30:00 JDT 2010 
Fri Feb 19 19:30:00 PST 2010 

输出：

Sat Mar 06 09:00:00 ICST 2010 => 2010-03-06 02:00:00 
Fri Feb 19 19:30:00 JDT 2010 => 2010-02-19 10:30:00 
Fri Feb 19 19:30:00 PST 2010 => 2010-02-20 03:30:00

支持你想查询，存储在格林尼治标准时间加上偏移（即，从格林尼治标准时间从API的本地时间）的时间。请注意，下面的代码假设，如果str2time可以解析给定的时间，strptime也可以。更改环路

my @dates; 
while (<DATA>) { 
    chomp; 
    warn("$0: failed conversion for $_\n"), next 
    unless defined(my $time_t = str2time $_); 

    my $zone = (strptime $_)[-1]; 
    my @t = gmtime($time_t); 
    push @dates => [ strftime("%Y-%m-%d %H:%M:%S", @t) 
       , sprintf("%+03d:%02d", 
          int($zone/3600), 
          int($zone % 3600)/60) 
       , $_ 
       ]; 
} 

随着收集的时间，呈现为SQL：

print "DROP TABLE IF EXISTS dates;\n", 
     "CREATE TABLE dates (date DATETIME, offset CHAR(6));\n", 
     "INSERT INTO dates (date,offset) VALUES\n", 
     join(",\n\n" => 
      map(" -- $_->[2]\n" . 
       " ('$_->[0]','$_->[1]')", @dates)), 
     ";\n", 
     "SELECT CONVERT_TZ(date,'+00:00',offset) FROM dates;\n" 

输出是

DROP TABLE IF EXISTS dates; 
CREATE TABLE dates (date DATETIME, offset CHAR(6)); 
INSERT INTO dates (date,offset) VALUES 
    -- Sat Mar 06 09:00:00 ICST 2010 
    ('2010-03-06 02:00:00','+07:00'), 

    -- Fri Feb 19 19:30:00 JDT 2010 
    ('2010-02-19 10:30:00','+09:00'), 

    -- Fri Feb 19 19:30:00 PST 2010 
    ('2010-02-20 03:30:00','-08:00'); 
SELECT CONVERT_TZ(date,'+00:00',offset) FROM dates; 

而且我们可以把它管mysql：

$ ./prog.pl | mysql -u username -D dbname 
CONVERT_TZ(date,'+00:00',offset) 
2010-03-06 09:00:00 
2010-02-19 19:30:00 
2010-02-19 19:30:00

Answer 2

尝试使用DateTime模块。

Answer 3

存储日期时，应始终使用UTC存储它们。这样，您可以从数据库中获取它们，并根据需要将它们转换为适当的时区，以便向用户显示。

为了在Perl中正确处理日期时间，我衷心推荐DateTime套件，该套件具有用于各种输入和输出格式的解析器和格式器。

我不知道，如果在你的OP所列日期的标准格式，但如果没有，那将是很容易构建从他们DateTime格式：

my $str = 'Sat Mar 06 09:00:00 ICST 2010'; 
my ($month, $day, $hour, $min, $sec, $tz, $year) = ($str =~ m{\w{3}\s(\w{3})\s(\d{2})\s(\d{2}):(\d{2}):(\d{2})\s(\w+)\s(\d{4})}); 

my $dt = DateTime->new(year => $year, month => $month, day => $day, 
         hour => $hour, minute => $min, second => $sec, 
         time_zone => $tz); 

然后，您可以使用DateTime::Format::MySQL将日期转换为与MySQL兼容的日期时间。

Answer 4

您可能必须明确告诉DateTime构造函数您正在处理哪些时区，因为三个和四个字母的代码不是唯一的，也不是标准化的。

我建议从DateTime::TimeZone开始，如果在列表中找不到要查找的内容，则可能会为时区创建新类型。你也可以找到一个符合你的语法的DateTime格式器（它们的数量很多），但是否则简单地使用正则表达式来提取日期和时间字段并将它传递给DateTime构造函数并不困难。

一旦你得到了你的字符串解析与正确设置的时间datetime对象，这是一点问题都没有将它们转换回来了到MySQL时间戳：只需使用DateTime::Format::MySQL：

my $string = DateTime::Format::MySQL->format_datetime($dt);