如何定义希伯来周年纪念日出现在组织议程中？

Question

如何定义希伯来周年纪念日（如生日）以显示在组织议程？最好的办法是通过BBDB做到这一点。到目前为止，我设法向BBDB添加周年纪念日/生日，并将其显示在org-agenda中。现在我需要转到下一步，并将这些日期提供为希伯来语日期。在日记模式中，日期看起来像HSivan 17,5766。但是，如果我将其插入BBDB，如anniversary: HSivan 17, 5776 birthday - 我在尝试生成议程视图时遇到错误：bad-sexp at line 5 /path/to/agenda.org (org-bbdb-anniversaries)。也许还有其他方法（没有BBDB），也许我可以直接在.org文件中列出它们？

Answer 1

在一般情况下，组织模式不处理好（或全部）具有比其他日历ISO为主，西部日历。

如果要在bbdb中存储不同格式的日期，可以使用 自定义org-bbdb-extract-date-fun。你将不得不编写自己的函数来解析希伯来语日期并返回（月日）。

这将允许您使用希伯来语日期使用bbdb数据库，但它会而不是存在，例如，使用希伯来语日期的日程表输出。这是一个更难的问题，特别是因为ISO日历假设渗透到组织模式代码库。

编辑：下面是需要一个字符串，如“Heshvan 17日，5776”作为参数并产生（月，日，年）的函数元组组织可以使用：

;;; This function uses functions and variables defined in calendar.el 
;;; and cal-hebrew.el 

(require 'calendar) 
(require 'cal-hebrew) 

(defun org-bbdb-anniv-extract-hebrew-date (date-string) 
    "Parse the string, assumed to be in the form \"MONTHNAME day, 
    year\", using Hebrew month names. Day is an integer, roughly 
    between 1 and 30 (the range depends on the month and the 
    year), and year is an integer representing a Hebrew calendar 
    year (roughly 5776 ~= 2015)." 
    (let* ((date-list (split-string date-string)) 
      (month-name (nth 0 date-list)) 
      (day (string-to-number (nth 1 date-list))) 
      (year (string-to-number (nth 2 date-list))) 
      (month-array (if (calendar-hebrew-leap-year-p year) 
          calendar-hebrew-month-name-array-leap-year 
          calendar-hebrew-month-name-array-common-year)) 
      (month (cdr (assoc-string 
         month-name 
         (calendar-make-alist month-array 1))))) 
     (calendar-gregorian-from-absolute 
     (calendar-hebrew-to-absolute (list month day year))))) 

;; test: (org-bbdb-anniv-extract-hebrew-date "Heshvan 17, 5776") ==> (10 30 2015) 
;; test: (org-bbdb-anniv-extract-hebrew-date "Heshvan 17, 3762") ==> (10 22 1) 
;; I hope these are right. 

;; To get org-bbdb to use this function to read dates from the BBDB 
;; database, instead of the standard org-bbdb-anniv-extract-date, do 
;; this: 

;; (setq org-bbdb-extract-date-fun #'org-bbdb-anniv-extract-hebrew-date) 

;; N.B. *ALL* dates in the BBDB database will be read using this 
;; function, so *ALL* of them must be Hebrew calendar dates. There is 
;; no provision for dates in different formats. To do that, one would 
;; need to write a function that can recognize dates in different 
;; formats (probably using heuristics) and then call the right 
;; conversion function. That's beyond the scope of this answer. 

;; Also, calendrical calculations are notoriously difficult to get 
;; right: this is no exception. In particular, the month calculation 
;; is probably valid only for dates in the Common Era, i.e. for years 
;; >= 3762. cal-hebrew.el has more details. But in any case, no 
;; guarantees: if it breaks, you get to keep the pieces. 

Answer 2

我相信你可以把这个在您的.emacs解决您的BBDB问题：

(require 'org-bbdb)