xsl转换删除双标签

Question

我有索姆XML我需要转换以删除双标签。

原来我用：

<xsl:template match="*[name()=name(../..)]"></xsl:template> 
<xsl:template match="*[name()=name(../../..)]"></xsl:template> 
<xsl:template match="*[name()=name(..)]"> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:template> 

一起除去内部的两个标签名称相同。但是，如果只有一个内部标签，那只能工作得很好。

我：

<a> 
<a> 
    <b>xxxx</b> 
    <c>xxxx</c> 
</a> 
<a> 
    <b>yyyy</b> 
    <c>yyyy</c> 
</a> 
</a> 

我想结束了：

<a> 
    <b>xxxx</b> 
    <c>xxxx</c> 
</a> 
<a> 
    <b>yyyy</b> 
    <c>yyyy</c> 
</a> 

不是：

<a> 
    <b>xxxx</b> 
    <c>xxxx</c> 
    <b>yyyy</b> 
    <c>yyyy</c> 
</a> 

我还不是很了解XSL转换与搜索语法，所以我希望有人能帮助我。

Answer 1

以下样式表将删除外（父）元件，其孩子们都具有相同的名称：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<!-- exception for parent whose children have all the same name --> 
<xsl:template match="*[*][not(*[name()!=name(..)])]"> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:template> 

</xsl:stylesheet> 

当上述被施加到下面的测试输入：

<root> 
    <a> 
     <a> 
      <b>bbb</b> 
      <c>ccc</c> 
     </a> 
     <a> 
      <d> 
       <d>ddd</d>  
      </d> 
      <e>eee</e> 
      <f> 
       <f>fff</f> 
       <g>ggg</g> 
      </f> 
     </a> 
    </a> 
</root> 

结果将会是：

<?xml version="1.0" encoding="UTF-8"?> 
<root> 
    <a> 
     <b>bbb</b> 
     <c>ccc</c> 
    </a> 
    <a> 
     <d>ddd</d> 
     <e>eee</e> 
     <f> 
     <f>fff</f> 
     <g>ggg</g> 
     </f> 
    </a> 
</root> 

Answer 2

而不是在它的名字听起来像你真的要删除的父时，它的名字是一样的所有子女的父或母，匹配消除孩子：

<xsl:template match="@*|node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()" /> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="*[*][not(*[name() != name(..)])]"> 
    <xsl:apply-templates select="@*|node()" /> 
</xsl:template> 

可以读取第二匹配表达式为“任何具有至少一个子元素的元素X，也没有任何具有不同于X的名称的子元素”。