按歌手名字开头的iTunes歌曲数量以字母开头

Question

我是Applescript的新手。我想要一个脚本来列出艺术家和该艺术家文件夹中的歌曲数量。我只想为名字以A开头的艺术家做这件事。当我准备好后，我会得到名字以B开头的艺术家名单，等等。我确实发现了这篇文章：“iOS中检索特定艺术家的歌曲数量的最快方法是什么？”也许这个脚本会工作，但我不知道如何修改这条线“if（artistName！= nil）”来获得我想要的。此外，我不知道信息的存储位置，所以我可以检索它“//存储新计数 [artists setObject：[NSNumber numberWithInt：numSongs] forKey：artistName];哦，我没有使用iOS我会是使用OSX。也许我可以修改这个剧本，我发现，它由艺术家得到专辑的数量。

MPMediaQuery *albumQuery = [MPMediaQuery albumsQuery]; 
NSArray *albumCollection = [albumQuery collections]; 
NSCountedSet *artistAlbumCounter = [NSCountedSet set]; 
[albumCollection enumerateObjectsUsingBlock:^(MPMediaItemCollection *album, NSUInteger idx, BOOL *stop) { 
NSString *artistName = [[album representativeItem] valueForProperty:MPMediaItemPropertyArtist]; 
[artistAlbumCounter addObject:artistName]; 
}]; 
NSLog(@"Artist Album Counted Set: %@", artistAlbumCounter); 

我感谢所有帮助，您可以提供。谢谢！

Answer 1

这是没有意义的看看iOS代码和ObjectiveC，以便弄清楚你应该怎么处理Applescript！无论如何，这里就是你想要的。

tell application "iTunes" 
    # Get playlist currently selected 
    set myPlayList to view of window 1 

    set s to (every track in myPlayList whose artist begins with "g") 
    repeat with t in s 
     log name of t 
    end repeat 
    log (count of s) 
end tell 

Answer 2

这一个使用selected playlist（或者，如果由于某种原因失败，整个库），并从A到Z。用您的代码替换log部件。要看它是如何工作的，请确保在Script-Editor它显示Log并为更好的视图选择Messages选项卡。只处理file tracks。

tell application "iTunes" 
    try 
     set selectedPlayList to view of window 1 
    on error 
     beep 
     set selectedPlayList to (container of browser window 1) -- whole library (I think) 
    end try 
end tell 

set totalItems to 0 

repeat with i from (id of "A") to (id of "Z") 

    set thisLetter to (character id i) 

    log "-----------------------------------------------------------" 

    tell application "iTunes" 
     try 

      set currentItems to (file tracks in selectedPlayList whose artist begins with thisLetter) 
      set countItems to number of items in currentItems 
      set totalItems to totalItems + countItems 

      set s to "s" 
      if countItems = 1 then set s to "" 
      log (countItems as text) & " item" & s & " for artists starting with the letter " & quoted form of thisLetter 
      log "-----------------------------------------------------------" 

      repeat with i from 1 to countItems 
       set thisItem to item i of currentItems 

       tell thisItem -- this is like "tell file track x". Shortens the code because we can use "artist" instead of "artist of thisItem" 

        log (i as text) & ". " & quoted form of (get artist) & " | " & quoted form of (get name) & " [ " & time & " ] " 

       end tell 

      end repeat 


     on error the error_message number the error_number 
      beep 
      display dialog "Error: " & the error_number & ". " & the error_message buttons {"OK"} default button 1 
      return 
     end try 

    end tell 

end repeat 


log "-----------------------------------------------------------" 
log "Items: " & totalItems as text