Haskell - 计算列表中每个不同元素的出现次数

Question

我是Haskell的新手，我只是想写一个列表理解来计算列表中每个不同值的频率，但是我遇到了问题最后一部分..

到目前为止，我有这样的：

frequency :: Eq a => [a] -> [(Int,a)] 
frequency list = [(count y list,y) | y <- rmdups ] 

某处有问题，涉及rmdups的最后一部分。

count函数需要一个字符，然后字符列表，告诉你如何字符经常发生，代码如下..

count :: Eq a => a -> [a] -> Int 
count x [] = 0 
count x (y:ys) | x==y = 1+(count x ys) 
       | otherwise = count x ys 

感谢你提前。

Answer 1

您的rmdups功能只是nub从Data.List。

Answer 2

我不得不代替Eq使用Ord因为使用sort

frequency :: Ord a => [a] -> [(Int,a)] 
frequency list = map (\l -> (length l, head l)) (group (sort list)) 

Answer 3

假设rmdups有那么你就错过了它的参数类型

rmdups :: Eq a => [a] -> [a] 

。

frequency :: Eq a => [a] -> [(Int,a)] 
frequency list = [(count y list,y) | y <- rmdups list] 

但是，您得到的错误将有助于诊断。

Answer 4

替换rmdups与nub list为我工作就像一个魅力。

Answer 5

你也可以使用一个关联数组/有限地图存储从列表元素的计数的关联，而你计算频率：

import Data.Map (fromListWith, toList) 

frequency :: (Ord a) => [a] -> [(a, Int)] 
frequency xs = toList (fromListWith (+) [(x, 1) | x <- xs]) 

实例：中

> frequency "hello world" 
[(' ',1),('d',1),('e',1),('h',1),('l',3),('o',2),('r',1),('w',1)] 

查看文档fromListWith和toList。

Answer 6

按照要求，这里是一个使用Control.Arrow一个解决方案：

frequency :: Ord a => [a] -> [(Int,a)] 
frequency = map (length &&& head) . group . sort 

这是相同的功能，ThePestest的回答，除了

λl -> (length l, head l) 

被替换

-- simplified type signature 
(&&&) :: (a -> b) -> (a -> c) -> a -> (b, c) 

从Control.Arrow。如果你想避免进口，

liftA2 (,) :: Applicative f => f a -> f b -> f (a, b) 

作品，以及（使用(->) r应用型实例）