需要pandoc批处理命令

Question

我有一个目录中有子目录，我试图将docx转换为html。 到目前为止，我发现这个命令：

@ECHO off 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 
CALL pandoc -o -s "%filename%".html --self-contained "%filename%".docx 
GOTO selectfile 

的问题是它的问我的文件名，我必须把这个蝙蝠文件中的每个子文件夹内做的工作。 我想进行一些更改，以便自动检测子文件夹并将所有docx文件转换为具有相同名称的html文件。 这是可能的家伙？ 任何人都可以修改此脚本？ 非常感谢。

Answer 1

下面的注释代码片段可以帮助：

@echo OFF 
SETLOCAL EnableExtensions 

rem iterate all *.docx recursively 
for /f "delims=" %%G in ('dir /B /S *.docx 2^>NUL') do (

    rem check .html existence 
    if not exist "%%~dpnG.html" (

     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 

     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 

     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

编辑

我想做出一些改变，这样它会检测子 自动和转换所有的docx文件到html文件 具有相同的名称。

您可以嵌入上面的代码片段到你的脚本如下：

@echo OFF 
SETLOCAL EnableExtensions 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 

if not defined filename GOTO selectfile 

rem iterate all %filename%.docx recursively 
for /f "delims=" %%G in ('dir /B /S "%filename%.docx" 2^>NUL') do (
    rem check .html existence 
    if not exist "%%~dpnG.html" (
     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 
     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 
     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

GOTO selectfile 

资源（必读）：

• （命令参考）An A-Z Index of the Windows CMD command line
• （额外的特殊性）Windows CMD Shell Command Line Syntax
• （%~G等特殊页）Command Line arguments (Parameters)
• （2>NUL等特殊页）Redirection