给处理指令添加一个唯一的id（xsl）

Question

我想重命名一个处理指令，同时为它添加一个唯一的id属性。我的输入是这样的：

?xml version="1.0" encoding="utf-8" ?> 
 
<material xml:lang="en-us"> 
 
    <title> 
 
    <?PI_start author="joepublic" comment="Comment #1" ?>Discovering 
 
     <?PI_end?>XML 
 
    </title> 
 
    <related-stuff> 
 
    <?PI_start author="johndoe" comment="Comment #3" ?> 
 
     <a href="otherdoc.xml" /> 
 
     <?PI_end?> 
 
    </related-stuff> 
 
</material>

结果是这样的：

<?xml version="1.0" encoding="utf-8"?> 
 
<material xml:lang="en-us"> 
 
    <title> 
 
    <?otherPI_start author="joepublic" comment="Comment #1" id ="1" ?>Discovering 
 
    <?otherPI_end id ="1" ?>XML 
 
    </title> 
 
    <related-stuff> 
 
    <?otherPI_start author="johndoe" comment="Comment #3" id ="2" ?> 
 
    <a href="otherdoc.xml" /> 
 
    <?otherPI_end id ="2"?> 
 
    </related-stuff> 
 
</material>

请注意，我有两个ID的产生，ID =” 1“表示文档中遇到的第一条指令，第二条表示id =”2“。 另请注意，ID在其他PI_end处理指令中重复。

你能帮我确定xsl中的匹配语句吗？

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
 
    <xsl:output method="xml" indent="yes" /> 
 
    <xsl:template match="node()|@*"> 
 
    <xsl:copy> 
 
     <xsl:apply-templates select="node()|@*" /> 
 
    </xsl:copy> 
 
    </xsl:template> 
 
    <xsl:template match="processing-instruction('PI_start')"> 
 
    <xsl:processing-instruction name="otherPI_start"> 
 
     author="<xsl:value-of select="substring-before(substring-after(.,'author=&quot;'),'&quot;')"/>" 
 
     comment="<xsl:value-of select="substring-before(substring-after(.,'comment=&quot;'),'&quot;')"/>" 
 
     id="<!-- What should I put here??? -->" 
 
    </xsl:processing-instruction> 
 
    </xsl:template> 
 
    <xsl:template match="processing-instruction('PI_end')"> 
 
    <xsl:processing-instruction name="otherPI_end"> 
 
     id="<!-- What should I put there??? -->" 
 
    </xsl:processing-instruction> 
 
    </xsl:template> 
 
</xsl:stylesheet>

Answer 1

id="<!-- What should I put here??? -->"

<xsl:value-of select="generate-id()"/> 

---

如果你想的<?PI_end?>的ID，以匹配先前<?PI_start ?>的，然后使用：

<xsl:value-of select="generate-id(preceding-sibling::processing-instruction('PI_start')[1])"/> 

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="processing-instruction('PI_start')"> 
    <xsl:processing-instruction name="otherPI_start"> 
     <xsl:value-of select="."/> 
     <xsl:text>id="</xsl:text> 
     <xsl:value-of select="generate-id()"/> 
     <xsl:text>"</xsl:text> 
    </xsl:processing-instruction> 
</xsl:template> 

<xsl:template match="processing-instruction('PI_end')"> 
    <xsl:processing-instruction name="otherPI_end"> 
     <xsl:text>id="</xsl:text> 
     <xsl:value-of select="generate-id(preceding-sibling::processing-instruction('PI_start')[1])"/> 
     <xsl:text>"</xsl:text> 
    </xsl:processing-instruction> 
</xsl:template>  

</xsl:stylesheet> 

Answer 2

你可以利用xsl:number这里

<xsl:template match="processing-instruction('PI_start')"> 
<xsl:processing-instruction name="otherPI_start"> 
    author="<xsl:value-of select="substring-before(substring-after(.,'author=&quot;'),'&quot;')"/>" 
    comment="<xsl:value-of select="substring-before(substring-after(.,'comment=&quot;'),'&quot;')"/>" 
    id="<xsl:number count="processing-instruction('PI_start')" level="any" />" 
</xsl:processing-instruction> 
</xsl:template> 

如果你觉得这不计算当前处理指令（这将意味着从零开始编号），尝试这取而代之....

<xsl:number count="/|processing-instruction('PI_start')" level="any" />