Vim的隐藏功能，还是让我搬过来的所有字符

Question

这是我做的
:syntax match conceal Test +[A-Z0-9]\{6}+
:set conceallevel=2
:set concealcursor=nvi
所以，当我在写的vim我123456希望它是什么也没有。但是当我移动到那个区域时实际发生的事情是，我必须沿着我想移动光标的方向移动6次以通过该区域。

有没有办法解决这个问题？我想让vim看到它，就好像这里什么都没有，当我移过那个区域时，就像没有任何东西一样。但我仍然希望能够搜索并删除它。

Answer 1

目前没有内置的方法来做到这一点。您可以使用synconcealed()，以确定是否有光标，它隐藏在什么隐蔽的字符并重新映射所有移动键尊重：像这样：

function! ForwardSkipConceal(count) 
    let cnt=a:count 
    let mvcnt=0 
    let c=col('.') 
    let l=line('.') 
    let lc=col('$') 
    let line=getline('.') 
    while cnt 
     if c>=lc 
      let mvcnt+=cnt 
      break 
     endif 
     if stridx(&concealcursor, 'n')==-1 
      let isconcealed=0 
     else 
      let [isconcealed, cchar, group]=synconcealed(l, c) 
     endif 
     if isconcealed 
      let cnt-=strchars(cchar) 
      let oldc=c 
      let c+=1 
      while c<lc && synconcealed(l, c)[2]==group | let c+=1 | endwhile 
      let mvcnt+=strchars(line[oldc-1:c-2]) 
     else 
      let cnt-=1 
      let mvcnt+=1 
      let c+=len(matchstr(line[c-1:], '.')) 
     endif 
    endwhile 
    return ":\<C-u>\e".mvcnt.'l' 
endfunction 
nnoremap <expr> l ForwardSkipConceal(v:count1) 

。注意：这只适用于单个运动（l）和正常模式，只是为了显示它可能完成的方式。

Answer 2

ZyX从上面的解决方案对我来说并不适用：显然隐藏文本区域的ID可以在遍历时改变，导致运动过早停止。

我一直在使用粘贴在下面的替代版本（还有丢失的BackwardSkipConceal函数）。这不是很好，但在LaTeX文档或C++代码中替换数学字符时效果很好。

function! ForwardSkipConceal(count) 
    let cnt=a:count 
    let mvcnt=0 
    let c=col('.') 
    let l=line('.') 
    let lc=col('$') 
    let line=getline('.') 
    while cnt 
     if c>=lc 
      let mvcnt+=cnt 
      break 
     endif 
     if stridx(&concealcursor, 'n')==-1 
      let isconcealed=0 
     else 
      let [isconcealed, cchar, group] = synconcealed(l, c) 
     endif 
     if isconcealed 
      let cnt-=strchars(cchar) 
      let oldc=c 
      let c+=1 
      while c < lc 
       let [isconcealed2, cchar2, group2] = synconcealed(l, c) 
       if !isconcealed2 || cchar2 != cchar 
        break 
       endif 
       let c+= 1 
      endwhile 
      let mvcnt+=strchars(line[oldc-1:c-2]) 
     else 
      let cnt-=1 
      let mvcnt+=1 
      let c+=len(matchstr(line[c-1:], '.')) 
     endif 
    endwhile 
    return ":\<C-u>\e".mvcnt.'l' 
endfunction 

function! BackwardSkipConceal(count) 
    let cnt=a:count 
    let mvcnt=0 
    let c=col('.') 
    let l=line('.') 
    let lc=0 
    let line=getline('.') 
    while cnt 
     if c<=1 
      let mvcnt+=cnt 
      break 
     endif 
     if stridx(&concealcursor, 'n')==-1 || c == 0 
      let isconcealed=0 
     else 
      let [isconcealed, cchar, group]=synconcealed(l, c-1) 
     endif 
     if isconcealed 
      let cnt-=strchars(cchar) 
      let oldc=c 
      let c-=1 
      while c>1 
       let [isconcealed2, cchar2, group2] = synconcealed(l, c-1) 
       if !isconcealed2 || cchar2 != cchar 
        break 
       endif 
       let c-=1 
      endwhile 
      let c = max([c, 1]) 
      let mvcnt+=strchars(line[c-1:oldc-2]) 
     else 
      let cnt-=1 
      let mvcnt+=1 
      let c-=len(matchstr(line[:c-2], '.$')) 
     endif 
    endwhile 
    return ":\<C-u>\e".mvcnt.'h' 
endfunction 

nnoremap <expr> l ForwardSkipConceal(v:count1) 
nnoremap <expr> h BackwardSkipConceal(v:count1)