德尔福2007年变种类型初始化

Question

我想声明一个常量数组来验证输入对象所持有的类型属性。但我做的事情不正确，请在下面的代码看看：

// Record to hold Name-Value pair for checking entities 
TValues = record 
    Name : WideString; 
    Value : Variant; 
end; 

const 
coarrType1Properties : array[0..5] of TValues = 
( 
    (Name : 'HARDWARE'; Value : TRUE), 
    (Name : 'SOFTWARE'; Value : TRUE), 
    (Name : 'TAG'; Value : TRUE), 
    (Name : 'AUTHORIZED'; Value : TRUE), 
    (Name : 'ID'; Value : 700), 
    (Name : 'CODE'; Value : 0) 
); 

，但我得到的Delphi编译时错误的类型值，即该类型不能被初始化。如何防止这个错误？或者我们可以有替代解决方案等请协助...

Answer 1

对于这些（布尔，整数）等简单的类型，你可以用TVarData初始化和强制转换回Variant：

type 
    TValues = record 
    Name: WideString; 
    Value: TVarData; 
    end; 

const 
    coarrType1Properties : array[0..5] of TValues = (
    (Name: 'HARDWARE'; Value: (VType: varBoolean; VBoolean: True)), 
    (Name: 'SOFTWARE'; Value: (VType: varBoolean; VBoolean: True)), 
    (Name: 'TAG'; Value: (VType: varBoolean; VBoolean: True)), 
    (Name: 'AUTHORIZED'; Value: (VType: varBoolean; VBoolean: True)), 
    (Name: 'ID'; Value: (VType: varInteger; VInteger: 700)), 
    (Name: 'CODE'; Value: (VType: varInteger; VInteger: 0)) 
); 

procedure Test; 
var 
    I: Integer; 
begin 
    for I := Low(coarrType1Properties) to High(coarrType1Properties) do 
    Writeln(Format('coarrType1Properties[%d]: ''%s'', %s', [I, coarrType1Properties[I].Name, VarToStr(Variant(coarrType1Properties[I].Value))])); 
end; 

Answer 2

E2071：变量不能用常量表达式初始化。

Answer 3

形式D2007帮助： E2071：这种类型不能初始化

文件类型（包括类型文本）和变量不能被初始化的类型，也就是说，你不能声明类型的常量或这些类型的初始化的变量。

program Produce; 

var 
    V: Variant = 0; 

begin 
end. 

//该示例尝试声明Variant类型的初始化变量，该变量非法。

program Solve; 

var 
    V: Variant; 

begin 
    V := 0; 
end. 

解决方法是用赋值语句初始化一个普通变量。

Answer 4

的documentation状态：

文件类型（包括类型文本），以及变型不能初始化，也就是说，你不能声明类型的常量或这些类型的初始化的变量。

所以你的问题是你的变种记录成员。这意味着你需要一个不同的方法，你将不得不放弃使用一个常量数组。

function Values(const Name: WideString; const Value: Variant): TValues; 
begin 
    Result.Name := Name; 
    Result.Value := Value; 
end; 

type 
    TValuesArray = array of TValues; 

function ValuesArray(const Values: array of TValues): TValuesArray; 
var 
    i: Integer;  
begin 
    SetLength(Result, Length(Values)); 
    for i := 0 to high(Result) do 
    Result[i] := Values[i]; 
end; 

var 
    coarrType1Properties: TValuesArray; 

initialization 
    coarrType1Properties := ValuesArray([ 
    Values('HARDWARE', TRUE), 
    Values('SOFTWARE', TRUE), 
    Values('TAG', TRUE), 
    Values('AUTHORIZED', TRUE), 
    Values('ID', 700), 
    Values('CODE', 0) 
    ]);