如何使用2个或更多类实现相同的方法？

Question

我想写一个TCheckBox和TRadioButton后代有3种相同的方法。

TMyCheckBox = class(TCheckBox) 
    procedure DoSomething1; 
    procedure DoSomething2; 
    procedure WMSize(var Message: TWMSize); message WM_SIZE; 
end; 

TMyRadioButton = class(TRadioButton) 
    procedure DoSomething1; 
    procedure DoSomething2; 
    procedure WMSize(var Message: TWMSize); message WM_SIZE; 
end; 

// the following procedures are common for both classes, so in fact 
// TMyCheckBox.DoSomething1 do the same as TMyRadioButton.DoSomething1 

procedure DoSomething1; 
begin 
    // here is the same code for TMyCheckBox as well as for TMyRadioButton 
    // but I don't want to write the same code many times but implement it 
    // for both classes at once in some common way 
end; 

procedure DoSomething2; 
begin 
    // here is the same code for TMyCheckBox as well as for TMyRadioButton 
    // but I don't want to write the same code many times but implement it 
    // for both classes at once in some common way 
end; 

procedure WMSize(var Message: TWMSize); message WM_SIZE; 
begin 
    // here is the same code for TMyCheckBox as well as for TMyRadioButton 
    // but I don't want to write the same code many times but implement it 
    // for both classes at once in some common way 
end; 

我该怎么做？

Answer 1

用三个方法签名定义一个接口说​​。

然后改变你的类声明

TMyCheckBox = class(TCheckBox, IDoSomething) 

，然后实现。

如果实现是常见或非常接近。

然后定义一个帮助类TDoSomething然后委派工作。

例如

Procedure TMyCheckBox.DoSomething1; // implements IDoSomething1 
Begin 
    TDoSomething.DoSomething1(Self); // given class method will suffice. 
End; 

类delphi中的方法，等同于其他语言中的静态方法。

Type 
    TDoSomethingHelper = Class(TObject) 
    Public 
     Class Procedure DoSomething1(aComponent : TComponent); 
    End; 

... 
implementation 

Class Procedure TDoSomethingHelper.DoSomething1(aComponent : TComponent); 
Begin 
    aComponent.Tag = 27; 
End; 

Answer 2

您正在寻找实现继承而不是接口继承。如果你可以从一个共同的祖先派生类，这只能在Delphi中实现。这种限制是固有的，因为语言只支持单一继承。

你能做的最好的是这样的：

type 
    TMyWinControlExtender = class 
    private 
    FTarget: TWinControl; 
    public 
    constructor Create(Target: TWinControl); 
    procedure WMSize(var Message: TWMSize; out CallInherited: Boolean); 
    procedure DoSomething; 
    end; 

    TMyCheckBox = class(TCheckBox) 
    private 
    FExtender: TMyWinControlExtender; 
    protected 
    procedure WMSize(var Message: TWMSize); message WM_SIZE; 
    public 
    constructor Create(AOwner: TComponent); override; 
    destructor Destroy; override; 
    procedure DoSomething; 
    end; 

    TMyRadioButton = class(TRadioButton) 
    private 
    FExtender: TMyWinControlExtender; 
    protected 
    procedure WMSize(var Message: TWMSize); message WM_SIZE; 
    public 
    constructor Create(AOwner: TComponent); override; 
    destructor Destroy; override; 
    procedure DoSomething; 
    end; 

{ TMyWinControlExtender } 

constructor TMyWinControlExtender.Create(Target: TWinControl); 
begin 
    inherited Create; 
    FTarget := Target; 
end; 

procedure TMyWinControlExtender.WMSize(var Message: TWMSize; out CallInherited: Boolean); 
begin 
    if FTarget.... then 
    .... 
    CallInherited := ...; 
    //etc. 
end; 

procedure TMyWinControlExtender.DoSomething; 
begin 
    if FTarget.... then 
    .... 
    //etc. 
end; 

{ TMyCheckBox } 

constructor TMyCheckBox.Create(AOwner: TComponent); 
begin 
    inherited; 
    FExtender := TMyWinControlExtender.Create(Self); 
end; 

destructor TMyCheckBox.Destroy; 
begin 
    FExtender.Free; 
    inherited; 
end; 

procedure TMyCheckBox.DoSomething; 
begin 
    FExtender.DoSomething; 
end; 

procedure TMyCheckBox.WMSize(var Message: TWMSize); 
var 
    CallInherited: Boolean; 
begin 
    FExtender.WMSize(Message, CallInherited); 
    if CallInherited then 
    inherited; 
end; 

27:11 TMyRadioButton等

现在，你可以使用接口和委派，以减少一些样板的，但没有办法为了帮助使用像WMSize这样的消息处理程序。