德尔福自定义构造函数永远不会运行

Question

我新的德尔福，我在Delphi 6创建一个组件，但我不能让构造函数运行：

unit MyComms1; 
... 
type 
    TMyComms = class(TComponent) 
    public 
     constructor MyConstructor; 
    end; 
implementation 

constructor TMyComms.MyConstructor; 
begin 
    inherited; 
    ShowMessage('got here'); 
end; 

不要紧什么构造函数被调用，但是这个代码根本不运行构造函数。

编辑

由请求，这里是TMyComms类是如何初始化（这个码是在一个不同的文件名为TestComms.pas）：

unit TestComms; 

interface 

uses MyComms1, ... 

type 
    TForm1 = class(TForm) 
    MyCommsHandle = TMyComms; 
    ... 
    procedure BtnClick(Sender: TObject); 
    private 
    public 
    end; 
var 
    Form1: TForm1; 

implementation 

procedure TForm1.BtnClick(Sender: TObject); 
begin 
    MyCommsHandle.AnotherMyCommsProcedure; 
end; 

编辑2

阅读一些看起来像构造函数的答案必须在delphi中手动调用。它是否正确？如果是这样，那么这肯定是我的主要错误 - 我习惯于在__construct函数被自动调用，每当一个类被分配到一个句柄。

Answer 1

您的代码不遵循Delphi命名指南 - 构造函数应该命名为Create。

由于您没有发布实际调用ctor的代码，我想，您可能根本没有调用它。尝试将一个按钮添加到您的窗体，双击它，并添加以下代码：

procedure TForm1.Button1Click(Sender : TObject) 

var comms : TMyComms; 

begin 
    comms := TMyComms.MyConstructor; 
    comms.Free; 
end; 

顺便说一句，如果你从TComponent派生，你应该重写构造函数的参数 - 否则继承的方法可能无法正常工作。

interface 

type TMyComms = class(TComponent) 
    private 
    protected 
    public 
    constructor Create(AOwner : TComponent); override; 
    end; 

implementation 

constructor TMyComms.Create(AOwner : TComponent) 
begin 
    inherited Create(AOwner); 
    // Your stuff 
end; 

// Somewhere in code 
var comms : TMyComms; 

begin 
comms := TMyComms.Create(nil); 
end; 

Answer 2

很可能你没有调用TMyComms.MyConstructor来测试你的不寻常的被调用和使用的构造函数。标有// **的方式将是最常用的方式。

type 
    TMyComms = class(TComponent) 
    public 
     constructor MyConstructor; 
    // the usual override; 
    // constructor Create(Owner:TComponent);override; // **  
     constructor Create(AOwner:TComponent);overload; override; 
     constructor Create(AOwner:TComponent;AnOtherParameter:Integer);overload;  
    end; 

constructor TMyComms.Create(AOwner: TComponent); 
begin 
    inherited ; 
    ShowMessage('got here Create'); 
end; 

constructor TMyComms.Create(AOwner: TComponent; AnOtherParameter: Integer); 
begin 
    inherited Create(AOwner); 
    ShowMessage(Format('got here Create with new parametere %d',[AnOtherParameter])); 
end; 

constructor TMyComms.MyConstructor; 
begin 
    inherited Create(nil); 
    ShowMessage('got here MyConstructor'); 
end; 
procedure TForm1.Button1Click(Sender: TObject); 
begin 
    TMyComms.MyConstructor.Free; 
    TMyComms.Create(self).Free; 
    TMyComms.Create(self,1234).Free; 

end; 

Answer 3

您的自定义构造函数未被调用，因为您没有调用它。

MyComm := TMyComms.MyConstructor; 

但是，您在代码中也有错误。因为没有派生的构造函数，所以可以用简单的inherited继承。

type 
    TMyComms = class(TComponent) 
    public 
     constructor MyConstructor; 
    end; 
implementation 

constructor TMyComms.MyConstructor; 
begin 
    inherited Create(nil); // ! 
    ShowMessage('got here'); 
end; 

您可以使用简单的inherited如果您的自定义构造函数中使用相同的名称和参数，从现有的构造函数。

type 
    TMyComms = class(TComponent) 
    public 
     constructor Create(AOwner : TComponent); override; 
    end; 
implementation 

constructor TMyComms.Create(AOwner : TComponent); 
begin 
    inherited; // <- everything is fine 
    ShowMessage('got here'); 
end;