CUDA Mandelbrot集合

Question

这是一个顺序的Mandelbrot集合实现。

void mandelbrot(PGMData *I) 
{ 
    float x0,y0,x,y,xtemp; 
    int i,j; 
    int color; 
    int iter; 
    int MAX_ITER=1000; 
    for(i=0; i<I->height; i++) 
     for(j=0; j<I->width; j++) 
     { 
      x0 = (float)j/I->width*(float)3.5-(float)2.5; 
      y0 = (float)i/I->height*(float)2.0-(float)1.0; 
      x = 0; 
      y = 0; 
      iter = 0; 
      while((x*x-y*y <= 4) && (iter < MAX_ITER)) 
      { 
       xtemp = x*x-y*y+x0; 
       y = 2*x*y+y0; 
       x = xtemp; 
       iter++; 
      } 
      color = (int)(iter/(float)MAX_ITER*(float)I->max_gray); 
      I->image[i*I->width+j] = I->max_gray-color; 
     } 
} 

我想用CUDA将其并列化，但我似乎误解了一些东西，现在我被卡住了。我试过搜索互联网，但没有什么真正的好消息。

内核：

__global__ void calc(int *pos) 
{ 
    int row= blockIdx.y * blockDim.y + threadIdx.y; // WIDTH 
    int col = blockIdx.x * blockDim.x + threadIdx.x; // HEIGHT 
    int idx = row * WIDTH + col; 

    if(col > WIDTH || row > HEIGHT || idx > N) return; 

    float x0 = (float)row/WIDTH*(float)3.5-(float)2.5; 
    float y0 = (float)col/HEIGHT*(float)2.0-(float)1.0; 

    int x = 0, y = 0, iter = 0, xtemp = 0; 
    while((x*x-y*y <= 4) && (iter < MAX_ITER)) 
    { 
     xtemp = x*x-y*y+x0; 
     y = 2*x*y+y0; 
     x = xtemp; 
     iter++; 
    } 
    int color = 255 - (int)(iter/(float)MAX_ITER*(float)255); 
    __syncthreads(); 
    pos[idx] = color;//color;// - color; 

} 

内核启动是这样的：

dim3 block_size(16, 16); 
dim3 grid_size((N)/block_size.x, (int) N/block_size.y); 
calc<<<grid_size,block_size>>>(d_pgmData); 

这里是常量：

#define HEIGHT 512 
#define WIDTH 512 
#define N (HEIGHT*WIDTH) 

整个GPU功能

void mandelbrotGPU(PGMData *I) 
{ 
    int *pos = (int *)malloc(HEIGHT*WIDTH*sizeof(int)); 
    int *d_pgmData; 

    cudaMalloc((void **)&d_pgmData, sizeof(int)*WIDTH*HEIGHT); 


    cudaMemcpy(d_pgmData, pos ,HEIGHT*WIDTH*sizeof(int) ,cudaMemcpyHostToDevice); 

    dim3 block_size(16, 16); 
    dim3 grid_size((N)/block_size.x, (int) N/block_size.y); 
    calc<<<grid_size,block_size>>>(d_pgmData); 

    cudaMemcpy(pos,d_pgmData,HEIGHT*WIDTH*sizeof(int) ,cudaMemcpyDeviceToHost); 
    cudaFree(d_pgmData); 
    I->image = pos; 
} 

问题是：它要么返回垃圾或驱动程序崩溃。我真的很感谢一些建议，因为我很困难。

Answer 1

下面是您的代码的工作版本（使用OpenCV）：

#include "cuda_runtime.h" 
#include "device_launch_parameters.h" 
#include <iostream> 
#include <opencv2/core/core.hpp> 
#include <opencv2/highgui/highgui.hpp> 

using namespace cv; 
using namespace std; 

#define HEIGHT 512 // must be multiple of block_size.y 
#define WIDTH 512 // must be multiple of block_size.x 
#define MAX_ITER 10000 

void mandelbrotGPU(char*); 
__global__ void calc(char* image_buffer); 

#define cudaAssertSuccess(ans) { _cudaAssertSuccess((ans), __FILE__, __LINE__); } 
inline void _cudaAssertSuccess(cudaError_t code, char *file, int line) 
{ 
    if (code != cudaSuccess) { 
    fprintf(stderr,"_cudaAssertSuccess: %s %s %d\n", cudaGetErrorString(code), file, line); 
    exit(code); 
    } 
} 

int main(int argc, char** argv) 
{ 
    IplImage* image_output = cvCreateImage(cvSize(WIDTH, HEIGHT), IPL_DEPTH_8U, 1); 
    mandelbrotGPU(image_output->imageData); 
    cvShowImage("GPU", image_output); 
    waitKey(0); 
    cvReleaseImage(&image_output); 
} 

void mandelbrotGPU(char* image_buffer) 
{ 
    char* d_image_buffer; 
    cudaAssertSuccess(cudaMalloc(&d_image_buffer, WIDTH * HEIGHT)); 
    dim3 block_size(16, 16); 
    dim3 grid_size(WIDTH/block_size.x, HEIGHT/block_size.y); 
    calc<<<grid_size, block_size>>>(d_image_buffer); 
    cudaAssertSuccess(cudaPeekAtLastError()); 
    cudaAssertSuccess(cudaDeviceSynchronize()); 
    cudaAssertSuccess(cudaMemcpy(image_buffer, d_image_buffer, HEIGHT * WIDTH, cudaMemcpyDeviceToHost)); 
    cudaAssertSuccess(cudaFree(d_image_buffer)); 
} 

__global__ void calc(char* image_buffer) 
{ 
    int row = blockIdx.y * blockDim.y + threadIdx.y; // WIDTH 
    int col = blockIdx.x * blockDim.x + threadIdx.x; // HEIGHT 
    int idx = row * WIDTH + col; 
    if(col >= WIDTH || row >= HEIGHT) return; 

    float x0 = ((float)col/WIDTH) * 3.5f - 2.5f; 
    float y0 = ((float)row/HEIGHT) * 3.5f - 1.75f; 

    float x = 0.0f; 
    float y = 0.0f; 
    int iter = 0; 
    float xtemp; 
    while((x * x + y * y <= 4.0f) && (iter < MAX_ITER)) 
    { 
    xtemp = x * x - y * y + x0; 
    y = 2.0f * x * y + y0; 
    x = xtemp; 
    iter++; 
    } 

    int color = iter * 5; 
    if (color >= 256) color = 0; 
    image_buffer[idx] = color; 
} 

输出：

最重要的变化：

• 删除__syncthreads();。该算法不使用其他线程生成的数据，因此不需要同步线程。
• 删除将主机缓冲区复制到设备。这是没有必要的，因为Mandelbrot算法写入整个设备缓冲区。
• 修复了错误的网格大小计算。
• 删除了主机内存的malloc，因为结果直接复制到OpenCV映像缓冲区中。
• 将缓冲区更改为使用字节而不是整数，当您拥有8位分辨率的单个灰色通道时更方便。
• 删除了一些不必要的浮标。当您将整数与浮点数一起使用时，整数会自动提升为浮点数。
• 固定两个问题在曼德尔布罗算法：
  • x和y被宣布为int s，而他们应该是float秒。
  • while循环中的第一个表达式应包含+而不是-。

Answer 2

只是一些想法来看待：

1. 没有必要__syncthreads()。你的线程不能相互通信。
2. 无需为I_WIDTH和I_HEIGHT创建设备内存。你只需将它们作为值传递（而不是指针或引用）。您确实需要设备内存pos。
3. 您需要检查所有CUDA功能的返回值（例如，cudaMalloc）并确保它们都可以。
4. 当你启动一个内核时，你的程序可以在GPU完成之前返回。有些情况下您需要等待明确完成;您可以在启动后通过拨打cudaDeviceSynchronize()来完成此操作。就你而言，你不必因为你的CUDA memcpy会等到内核完成。

Answer 3

这肯定是不正确的：

dim3 grid_size((N)/block_size.x, (int) N/block_size.y); 

这引起了界外访问的内核。您想要启动总共WIDTH x HEIGHT线程，其中一个用于图像中的每个像素。相反，您将启动N/16 x N/16个线程。

而且好像你在你的内核线程检查行（应阻止了界外，从错误的线程访问），但它没有正确表述：

if(col > WIDTH || row > HEIGHT || idx > N) return; 

例如，这允许idx = N通过线程检查，但这并不当通过内核的最后一行写了一个有效的内存位置：

pos[idx] = color; 

你可以修复这个线程检查有：

if(col >= WIDTH || row >= HEIGHT || idx >= N) return; 

其他一些意见：

• 你没有做任何proper cuda error checking
• 你可以看到在你的代码中的错误，如果你有cuda-memcheck

运行