Excel - 将基于单元格的公式替换为实际单元格值

Question

有没有办法将基于单元格的公式转换为公式中的单元格替换为其实际值？没有自动完成？

下面是一个例子，让我们只说其公式为：

=A1+A2+B6 

而且......

A1=2, A2=5 and B6=21. 

我怎样才能把我的公式从这个..

=A1+A2+B6 

...对此...

=2+5+21 

...没有手动做？我相信有一种方法。

谢谢。

Answer 1

这应该适用于所有公式引用位于同一张纸上的简单情况。我使用DirectPrecedents范围，但这限制了您在同一工作表上的先前单元格。

在我的例子我有，这Sheet1

|      A      | 
--+---------------------------------------------+ 
1 | 2           | 
2 | 4           | 
3 | 6           | 
4 | =Sheet1!A3+(A1^Sheet1!A1)+Sheet1!A2/(A3+A2) | 
5 | =SUM(A1,A2,A3)/COUNT(A1,A2,A3)    | 

注意单元格引用，其中包括与命名表前缀单元的组合。

而且我用这个VBA代码：

Option Explicit 

Sub Test() 
    PrintResolvedFormula Range("A4") 
    PrintResolvedFormula Range("A5") 
End Sub 

Sub PrintResolvedFormula(rng As Range) 

    If rng.HasFormula Then 

    Dim formula As String 
    formula = rng.FormulaR1C1 

    Dim cel As Range 
    For Each cel In rng.DirectPrecedents.Cells 
     formula = Replace(formula, cel.Worksheet.Name & "!", vbNullString) 
     formula = Replace(formula, cel.Address(False, False, xlR1C1, False, rng), cel.Text) 
    Next cel 

    Debug.Print formula 

    Else 

    Debug.Print rng.Value 

    End If 

End Sub 

并获得此输出：

=6+(2^2)+4/(6+4) 
=SUM(2,4,6)/COUNT(2,4,6) 

注意，是解析为值单元格引用，但它不能解决功能值。要解决个别功能，您需要分解函数字符串并使用Application.Evaluate。