给定一个（A * B）列表，返回（A * B列表）名单

Question

一个时髦的标题也许，但我遇到了下列问题：

鉴于(a * b) list类型的列表，我想创建一个类型为(a * b list) list的新列表。举例：

给定列表let testList = [(1,"c");(2,"a");(1,"b")]，我的函数应该返回[(1, ["c";"b"]; (2, ["a"])]。

我有以下的，但我对如何继续有点卡住：

let rec toRel xs = 
    match xs with 
    | (a,b)::rest -> (a,[b])::toRel rest 
    | _   -> [] 

Answer 1

您可以使用内置的功能List.groupBy然后映射删除多余的关键：

testList |> List.groupBy fst |> List.map (fun (k,v) -> (k, List.map snd v)) 

// val it : (int * string list) list = [(1, ["c"; "b"]); (2, ["a"])] 

否则，如果你想继续比赛，你可以做这样的事情：

let toRel x = 
    let rec loop acc xs = 
     match xs with 
     | (k, b) :: rest -> 
      let acc = 
       match Map.tryFind k acc with 
       | Some v -> Map.add k (b::v) acc 
       | None -> Map.add k [b] acc 
      loop acc rest 
     | _    -> acc 
    loop Map.empty x |> Map.toList 

或者使用Option.toList你可以写：

let toRel x = 
    let rec loop acc xs = 
     match xs with 
     | (k, b) :: rest -> 
      let acc = 
       let lst = Map.tryFind k acc |> Option.toList |> List.concat 
       Map.add k (b::lst) acc 
      loop acc rest 
     | _    -> acc 
    loop Map.empty x |> Map.toList