动态填充多维awk数组

我正在处理解析文件的Awk/Gawk脚本，为每行填充多维数组。第一列是以句点分隔的字符串，每个值都是对下一级别数组键的引用。第二列是值动态填充多维awk数组

这里是正在分析什么内容示例如下：

$ echo -e "personal.name.first\t= John\npersonal.name.last\t= Doe\npersonal.other.dob\t= 05/07/87\npersonal.contact.phone\t= 602123456\npersonal.contact.email\t= [email protected]\nemployment.jobs.1\t= Company One\nemployment.jobs.2\t= Company Two\nemployment.jobs.3\t= Company Three" 
personal.name.first  = John 
personal.name.last  = Doe 
personal.other.dob  = 05/07/87 
personal.contact.phone = 602123456 
personal.contact.email = [email protected] 
employment.jobs.1  = Company One 
employment.jobs.2  = Company Two 
employment.jobs.3  = Company Three

其中被解析后，林期待它具有相同的结构为：

data["personal"]["name"]["first"]  = "John" 
data["personal"]["name"]["last"]  = "Doe" 
data["personal"]["other"]["dob"]  = "05/07/87" 
data["personal"]["contact"]["phone"] = "602123456" 
data["personal"]["contact"]["email"] = "[email protected]" 
data["employment"]["jobs"]["1"]  = Company One 
data["employment"]["jobs"]["2"]  = Company Two 
data["employment"]["jobs"]["3"]  = Company Three

我卡在的部分是如何动态地在构造多维数组时填充键。

我发现this SO thread，涵盖了类似的问题，这是通过使用SUBSEP变量，起初似乎是因为我需要它的工作解决了，但一些测试后，它看起来像arr["foo", "bar"] = "baz"没有得到像对待真正的数组，如arr["foo"]["bar"] = "baz"会。什么，我的意思了一个例子是在阵列中任何级别的计数值不能：arr["foo", "bar"] = "baz"; print length(arr["foo"])只会打印0（零）

我发现this SO thread这有助于一点点，可能是指着我在正确的方向。

中提到在线程的代码段：

BEGIN { 
    x=SUBSEP 

    a="Red" x "Green" x "Blue" 
    b="Yellow" x "Cyan" x "Purple" 

    Colors[1][0] = "" 
    Colors[2][0] = "" 

    split(a, Colors[1], x) 
    split(b, Colors[2], x) 

    print Colors[2][3] 
}

是非常接近的，但我现在遇到的问题是，该密钥（例如：Red，Green等），需要指定动态地，并且可能有一个或多个键。

基本上，我怎么能走a_keys和b_keys字符串，通过.割裂开来，并填充a和b变量多维数组？..

BEGIN { 
    x=SUBSEP 

    # How can I take these strings... 
    a_keys = "Red.Green.Blue" 
    b_keys = "Yellow.Cyan.Purple" 

    # .. And populate the array, just as this does: 
    a="Red" x "Green" x "Blue" 
    b="Yellow" x "Cyan" x "Purple" 

    Colors[1][0] = "" 
    Colors[2][0] = "" 

    split(a, Colors[1], x) 
    split(b, Colors[2], x) 

    print Colors[2][3] 
}

任何帮助，将不胜感激，谢谢！

来源

2017-05-12 Justin

所有你需要的是：

BEGIN { FS="\t= " } 
{ 
    split($1,d,/\./) 
    data[d[1]][d[2]][d[3]] = $2 
}

看：

$ cat tst.awk 
BEGIN { FS="\t= " } 
{ 
    split($1,d,/\./) 
    data[d[1]][d[2]][d[3]] = $2 
} 
END { 
    for (x in data) 
     for (y in data[x]) 
      for (z in data[x][y]) 
       print x, y, z, "->", data[x][y][z] 
} 

$ awk -f tst.awk file 
personal other dob -> 05/07/87 
personal name first -> John 
personal name last -> Doe 
personal contact email -> [email protected] 
personal contact phone -> 602123456 
employment jobs 1 -> Company One 
employment jobs 2 -> Company Two 
employment jobs 3 -> Company Three

以上是呆子，具体当然，因为没有其他的awk支持真正的多维数组。

要填充的多维数组时的索引并不总是相同的深度（例如，大于3）的，这是相当复杂：

########## 
$ cat tst.awk 
function rec_populate(a,idxs,curDepth,maxDepth,tmpIdxSet) { 
    if (tmpIdxSet) { 
     delete a[SUBSEP]    # delete scalar a[] 
     tmpIdxSet = 0 
    } 
    if (curDepth < maxDepth) { 
     # We need to ensure a[][] exists before calling populate() otherwise 
     # inside populate() a[] would be a scalar, but then we need to delete 
     # a[][] inside populate() before trying to create a[][][] because 
     # creating a[][] below creates IT as scalar. SUBSEP used arbitrarily. 

     if (!((idxs[curDepth] in a) && (SUBSEP in a[idxs[curDepth]]))) { 
      a[idxs[curDepth]][SUBSEP] # create array a[] + scalar a[][] 
      tmpIdxSet = 1 
     } 
     rec_populate(a[idxs[curDepth]],idxs,curDepth+1,maxDepth,tmpIdxSet) 
    } 
    else { 
     a[idxs[curDepth]] = $2 
    } 
} 

function populate(arr,str,sep, idxs) { 
    split(str,idxs,sep) 
    rec_populate(arr,idxs,1,length(idxs),0) 
} 

{ populate(arr,$1,",") } 

END { walk_array(arr, "arr") } 

function walk_array(arr, name,  i) 
{ 
    # Mostly copied from the following URL, just added setting of "sorted_in": 
    # https://www.gnu.org/software/gawk/manual/html_node/Walking-Arrays.html 
    PROCINFO["sorted_in"] = "@ind_str_asc" 
    for (i in arr) { 
     if (isarray(arr[i])) 
      walk_array(arr[i], (name "[" i "]")) 
     else 
      printf("%s[%s] = %s\n", name, i, arr[i]) 
    } 
}

。

########## 
$ cat file 
a uno 
b,c dos 
d,e,f tres_wan 
d,e,g tres_twa 
d,e,h,i,j cinco 

########## 
$ awk -f tst.awk file 
arr[a] = uno 
arr[b][c] = dos 
arr[d][e][f] = tres_wan 
arr[d][e][g] = tres_twa 
arr[d][e][h][i][j] = cinco

来源

2017-05-12 21:46:43

我可能忘了提及的是，钥匙可能并不总是恰好有三个部分。但是，这是一个足够好的启动我与之合作。谢谢！ – Justin

然后你需要我发布的第二个解决方案。陈述明显 - 如果你的真实数据有多个细分市场，那么你的样本输入也应该有。 –

没有真正multidim阵列，你可以做多一点簿记

awk -F'\t= ' '{split($1,k,"."); 
       k1[k[1]]; k2[k[2]]; k3[k[3]]; 
       v[k[1],k[2],k[3]]=$2} 
      END {for(i1 in k1) 
       for(i2 in k2) 
        for(i3 in k3) 
        if((i1,i2,i3) in v) 
         print i1,i2,i3," -> ",v[i1,i2,i3]}' file 


personal other dob -> 05/07/87 
personal name first -> John 
personal name last -> Doe 
personal contact email -> [email protected] 
personal contact phone -> 602123456 
employment jobs 1 -> Company One 
employment jobs 2 -> Company Two 
employment jobs 3 -> Company Three

来源

2017-05-12 23:59:17 karakfa

动态填充多维awk数组

回答

相关问题