XDocument.Validate命名空间问题

Question

我修改了MSDN示例以反映我的问题。

当使用一个命名空间，我不能获取文档验证，因为我所期望的和验证的文档时，这并不具有不论它是否具有或不出错它验证一个名称空间。

Dim errors As Boolean = False 

Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs) 
    Console.WriteLine("{0}", e.Message) 
    errors = True 
End Sub 

Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument 
    For Each element As XElement In xDoc.Descendants 
     element.Name = ns + element.Name.LocalName 
    Next 
    Return xDoc 
End Function 

Sub Main() 
    Dim xsdMarkup As XElement = _ 
     <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com"> 
      <xsd:element name='Root'> 
       <xsd:complexType> 
        <xsd:sequence> 
         <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/> 
         <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/> 
        </xsd:sequence> 
       </xsd:complexType> 
      </xsd:element> 
     </xsd:schema> 
    Dim schemas As XmlSchemaSet = New XmlSchemaSet() 
    schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader) 

    Dim doc1 As XDocument = _ 
     <?xml version='1.0'?> 
     <Root> 
      <Child1>content1</Child1> 
      <Child2>content1</Child2> 
     </Root> 

    Dim doc2 As XDocument = _ 
     <?xml version='1.0'?> 
     <Root> 
      <Child1>content1</Child1> 
      <Child3>content1</Child3> 
     </Root> 

    Dim ns As XNamespace = "http://somenamespace.com" 
    doc1 = AddNameSpace(doc1, ns) 

    Console.WriteLine("Validating doc1") 
    errors = False 
    doc1.Validate(schemas, AddressOf XSDErrors) 
    Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated")) 

    Console.WriteLine() 
    Console.WriteLine("Validating doc2") 
    errors = False 
    doc2.Validate(schemas, AddressOf XSDErrors) 
    Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated")) 

End Sub 

输出：

验证DOC1

元素命名空间 '根''http://somenamespace.com具有无效子元素 'Child1' 在命名空间的“http：// somenamespace .COM”。预计可能的元素列表：'Child1'。

DOC1没有验证

验证DOC2

DOC2验证

Answer 1

那么你将需要添加elementFormDefault="qualified"到您的模式（在xsd:schema元素），如果你希望你的doc1你把命名空间每个元素都是有效的。使用你当前的模式，一个有效的实例将是Root位于targetNamespace中，但ChildX元素不在名称空间中。

第二个问题是架构验证和名称空间的已知问题，验证解析器查找根元素的匹配模式，如果没有，它会执行松散验证，所以您不会收到验证错误。使用XmlReader API，您可以要求在此情况下发出警告，但我不知道如何使用Validate方法执行此操作。所以你需要代码如

Imports System 
Imports System.Xml 
Imports System.Xml.Linq 
Imports System.Xml.Schema 

Module Module1 

    Dim errors As Boolean = False 

    Private Sub XSDErrors(ByVal o As Object, ByVal e As ValidationEventArgs) 
     Console.WriteLine("{0}", e.Message) 
     errors = True 
    End Sub 

    Private Function AddNameSpace(ByVal xDoc As XDocument, ByVal ns As XNamespace) As XDocument 
     For Each element As XElement In xDoc.Descendants 
      element.Name = ns + element.Name.LocalName 
     Next 
     Return xDoc 
    End Function 

    Sub Main() 
     Dim xsdMarkup As XElement = _ 
      <xsd:schema xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns="http://somenamespace.com" targetNamespace="http://somenamespace.com" elementFormDefault="qualified"> 
       <xsd:element name='Root'> 
        <xsd:complexType> 
         <xsd:sequence> 
          <xsd:element name='Child1' minOccurs='1' maxOccurs='1'/> 
          <xsd:element name='Child2' minOccurs='1' maxOccurs='1'/> 
         </xsd:sequence> 
        </xsd:complexType> 
       </xsd:element> 
      </xsd:schema> 
     Dim schemas As XmlSchemaSet = New XmlSchemaSet() 
     schemas.Add("http://somenamespace.com", xsdMarkup.CreateReader) 

     Dim doc1 As XDocument = _ 
      <?xml version='1.0'?> 
      <Root> 
       <Child1>content1</Child1> 
       <Child2>content1</Child2> 
      </Root> 

     Dim doc2 As XDocument = _ 
      <?xml version='1.0'?> 
      <Root> 
       <Child1>content1</Child1> 
       <Child3>content1</Child3> 
      </Root> 

     Dim ns As XNamespace = "http://somenamespace.com" 
     doc1 = AddNameSpace(doc1, ns) 

     Console.WriteLine("Validating doc1") 
     errors = False 
     doc1.Validate(schemas, AddressOf XSDErrors) 
     Console.WriteLine("doc1 {0}", IIf(errors = True, "did not validate", "validated")) 

     Console.WriteLine() 
     Console.WriteLine("Validating doc2") 
     Dim xrs As New XmlReaderSettings() 
     xrs.ValidationType = ValidationType.Schema 
     xrs.ValidationFlags = xrs.ValidationFlags Or XmlSchemaValidationFlags.ReportValidationWarnings 
     xrs.Schemas = schemas 
     AddHandler xrs.ValidationEventHandler, AddressOf XSDErrors 
     errors = False 
     Using xr1 As XmlReader = doc2.CreateReader() 
      Using xr2 As XmlReader = XmlReader.Create(xr1, xrs) 
       While xr2.Read() 

       End While 
      End Using 
     End Using 
     Console.WriteLine("doc2 {0}", IIf(errors = True, "did not validate", "validated")) 

    End Sub 

End Module