TSQL中的数据透视记录

Question

我的当前表格对于1个用户来说是这样的。

NewCustomerID OldCustomerID RowID  Date 
111    NULL    1  2016-01-01 
222    111    321  2016-02-05 
333    222    5433  2017-03-01 
444    333    95312 2017-04-03 

下表是我最终结果所需要的。需要TSQL。

NewCustomerID OldCustomerID 
444    111    
444    222    
444    333 

我将使用上表更新所有OldCustomerID的最新NewCustomerID

Answer 1

你正在寻找一个递归CTE：

with cte as (
     select t.NewCustomerID, t.OldCustomerID 
     from t 
     where not exists (select 1 from t t2 where t2.OldCustomerId = t.NewCustomerID) 
     union all 
     select cte.NewCustomerId, t.OldCustomerID 
     from cte join 
      t 
      on t.NewCustomerID = cte.OldCustomerID 
    ) 
select * 
from cte; 

Here是它的工作的例子。

Answer 2

试试这个

DECLARE @SampleDAta AS TABLE 
(
    NewCustomerID int, 
    OldCustomerID int 
) 
INSERT INTO @SampleDAta VALUES (111, NULL),(222,111),(333,222),(444,333),(1111, NULL),(2222,1111),(3333,2222),(4444,3333),(5555,4444) 

;with reTbl as (
     select t.NewCustomerID, t.OldCustomerID, 1 as lev, t.NewCustomerID AS RootId 
     from @SampleDAta t 
     where t.OldCustomerID IS NULL 
     union all 
     select t.NewCustomerId, t.OldCustomerID, reTbl.lev +1, reTbl.RootId 
     from reTbl join 
      @SampleDAta t 
      on t.OldCustomerID = reTbl.NewCustomerID 
    ), 
LastestId AS 
(
    SELECT c.RootId, max(c.lev) AS MaxLevel 
    FROM reTbl c 
    GROUP BY c.RootId 
) 

select reTbl.NewCustomerID, reTbl1.NewCustomerID AS OldCustomerID 
from reTbl 
INNER JOIN reTbl reTbl1 ON reTbl.RootId = reTbl1.RootId 
INNER JOIN LastestId t ON reTbl.RootId = t.RootId AND reTbl.lev = t.MaxLevel 
WHERE reTbl.NewCustomerID != reTbl1.NewCustomerID 
ORDER BY reTbl.NewCustomerID