nsis - 卸载任务栏上的固定图标

我正在为一家公司的应用程序工作，他们要求如果应用程序固定到任务栏上，卸载应用程序时应该取消固定。如果我只是从quicklaunch \ user pinned \ taskbar中删除图标，那么它会在任务栏上留下一个空白图标。nsis - 卸载任务栏上的固定图标

我需要以某种方式实际取消固定它。我遇到的唯一的事情是安装winshell插件（http://nsis.sourceforge.net/WinShell_plug-in），然后调用IStartMenuPinnedList :: RemoveFromList（https://msdn.microsoft.com/en-us/library/windows/desktop/bb774817(v=vs.85).aspx）

我宁愿不安装插件，如果我不需要。有没有人有什么建议？

来源

2017-03-15 picklechips

NSIS没有本接口支持，所以你必须使用插件。如果您想要避开第三方插件（由我撰写），则可以使用系统插件代替：

!include "LogicLib.nsh" 
!include "Win\COM.nsh" ; NSIS v3+ 

!macro UnpinShortcut lnkpath 
Push $0 
Push $1 
!insertmacro ComHlpr_CreateInProcInstance ${CLSID_StartMenuPin} ${IID_IStartMenuPinnedList} r0 "" 
${If} $0 P<> 0 
    System::Call 'SHELL32::SHCreateItemFromParsingName(ws, p0, g "${IID_IShellItem}", *p0r1)' "${lnkpath}" 
    ${If} $1 P<> 0 
     ${IStartMenuPinnedList::RemoveFromList} $0 '(r1)' 
     ${IUnknown::Release} $1 "" 
    ${EndIf} 
    ${IUnknown::Release} $0 "" 
${EndIf} 
Pop $1 
Pop $0 
!macroend 

Section Uninstall 
!insertmacro UnpinShortcut "$SMPrograms\MyApp.lnk" 
Delete "$SMPrograms\MyApp.lnk" 
SectionEnd

来源

2017-03-15 17:28:18 Anders

nsis - 卸载任务栏上的固定图标

回答

相关问题