快速在picturebox中加载图像

Question

我有一个程序，显示jpgs在小图片盒中的预览。这些图像的加载速度很慢，每个图像几乎需要一秒钟。这是因为图像很大（8/9 mB）。我需要快速加载它们，例如通过加载图片的大拇指。我想避免把所有内容都放入内存中，因为可能有数百张图片。

你对此有何建议？

THanks

Answer 1

您需要提前调整图片大小。

创建缩略图的速度同样缓慢，因为在开始制作缩略图之前，您需要阅读整个文件。

你可以做的就是，就像windows一样，创建一个tumbnail“数据库”，在这里你存储每张图片的tumbs。如果需要，只能使用全尺寸的图片。

所以，如果你有一个像，

picture001.jpg 
picture002.jpg 
picture003.jpg 

创建为每一个tumbs;

picture001.jpg 
picture001_tumb.jpg 
picture002.jpg 
picture002_tumb.jpg 
picture003.jpg 
picture003_tumb.jpg 

所以在picuters检测的加载中，如果_tumb.jpg存在，如果没有创建并存储它。当然，需要在后台工作人员完成，因为你需要你的主应用程序来响应...

你也可以使用此代码，从Windows外壳请求图标;

Imports System.Runtime.InteropServices 
Imports System 
Imports System.Drawing 
Imports System.Drawing.Imaging 
Imports System.Collections.Generic 
Imports System.Text 

' http://www.vbforums.com/showthread.php?617626-How-do-I-extract-a-256X256-image-out-of-an-icon&highlight=IShellItemImageFactory 

Module GetShellIcon 
    <Flags()> _ 
    Public Enum SIIGBF 
     SIIGBF_RESIZETOFIT = 0 
     SIIGBF_BIGGERSIZEOK = 1 
     SIIGBF_MEMORYONLY = 2 
     SIIGBF_ICONONLY = 4 
     SIIGBF_THUMBNAILONLY = 8 
     SIIGBF_INCACHEONLY = 16 
    End Enum 

    Public Enum SIGDN As UInteger 
     NORMALDISPLAY = 0 
     PARENTRELATIVEPARSING = &H80018001UI 
     PARENTRELATIVEFORADDRESSBAR = &H8001C001UI 
     DESKTOPABSOLUTEPARSING = &H80028000UI 
     PARENTRELATIVEEDITING = &H80031001UI 
     DESKTOPABSOLUTEEDITING = &H8004C000UI 
     FILESYSPATH = &H80058000UI 
     URL = &H80068000UI 
    End Enum 

    <ComImportAttribute(), GuidAttribute("bcc18b79-ba16-442f-80c4-8a59c30c463b"),  InterfaceTypeAttribute(ComInterfaceType.InterfaceIsIUnknown)> _ 
    Public Interface IShellItemImageFactory 
     Sub GetImage(ByVal size As SIZE, ByVal flags As SIIGBF, ByRef phbm As IntPtr) 
    End Interface 

    <ComImport()> <Guid("43826d1e-e718-42ee-bc55-a1e261c37bfe")>  <InterfaceType(ComInterfaceType.InterfaceIsIUnknown)> _ 
    Public Interface IShellItem 
     Sub BindToHandler(ByVal pbc As IntPtr, <MarshalAs(UnmanagedType.LPStruct)>  ByVal bhid As Guid, <MarshalAs(UnmanagedType.LPStruct)> ByVal riid As Guid, ByRef ppv As  IntPtr) 
     Sub GetParent(ByRef ppsi As IShellItem) 
     Sub GetDisplayName(ByVal sigdnName As SIGDN, ByRef ppszName As IntPtr) 
     Sub GetAttributes(ByVal sfgaoMask As UInt32, ByRef psfgaoAttribs As UInt32) 
     Sub Compare(ByVal psi As IShellItem, ByVal hint As UInt32, ByRef piOrder As  Integer) 
    End Interface 

    <DllImport("shell32.dll", CharSet:=CharSet.Unicode, PreserveSig:=False)> _ 
    Public Sub SHCreateItemFromParsingName(<MarshalAs(UnmanagedType.LPWStr)> ByVal  pszPath As String, ByVal pbc As IntPtr, <MarshalAs(UnmanagedType.LPStruct)> ByVal riid As  Guid, <MarshalAs(UnmanagedType.Interface, IidParameterIndex:=2)> ByRef ppv As IShellItem) 
    End Sub 

    <StructLayout(LayoutKind.Sequential)> _ 
    Public Structure SIZE 
     Public cx As Integer 
     Public cy As Integer 
     Public Sub New(ByVal cx As Integer, ByVal cy As Integer) 
      Me.cx = cx 
      Me.cy = cy 
     End Sub 
    End Structure 

    Public Function GetShellIcon(ByVal Path As String, MySIIGBF As SIIGBF, Optional ByVal Width As Integer = 256, Optional ByVal Height As Integer = 256) As Bitmap 

     Dim ppsi As IShellItem = Nothing 
     Dim hbitmap As IntPtr = IntPtr.Zero 
     Dim uuid As New Guid("43826d1e-e718-42ee-bc55-a1e261c37bfe") 

     Dim bs As Bitmap 

     SHCreateItemFromParsingName(Path, IntPtr.Zero, uuid, ppsi) 
     DirectCast(ppsi, IShellItemImageFactory).GetImage(New SIZE(Width, Height), MySIIGBF, hbitmap) 
     bs = System.Drawing.Bitmap.FromHbitmap(hbitmap) 
     bs.MakeTransparent(Color.Black) 

     Return bs 

    End Function 

End Module