使用XSLT进行简单XML重构

Question

我是XSLT的新手，我试图实现相当简单的重构。我有一个代表一个人的xml文档（出于说明目的）。我有许多元素。从这些我想提取first_name和last_name（和关键的其他）到一个新的full_name元素。我见过这个问题here。 “renameWrapped”方法起作用。但是它不够通用，因为我无法保证输入文档中元素的排序。

我有下面的XML：

<?xml version="1.0" encoding="utf-8"?> 
<myname:Person xmlns:myname="http://www.myname.co.uk/def"> 
    <myname:attr1>some value</myname:attr1> 
    <myname:first_name>john</myname:first_name> 
    <myname:last_name>smith</myname:last_name> 
    <myname:attr2>some value</myname:attr2> 
    <!-- other person stuff --> 
</myname:Person> 

这是由以下XSL转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:myname="http://www.myname.co.uk/def"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="@*|node()" name="identity"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="myname:Person"> 
     <myname:Person> 
      <xsl:copy> 
       <xsl:apply-templates select="@*|node()[local-name() != 'first_name' and local-name() != 'Person' and local-name() != 'last_name']"/> 
      </xsl:copy> 
      <myname:FullName> 
       <xsl:apply-templates select="myname:first_name | myname:last_name"/> 
      </myname:FullName> 
     </myname:Person> 
    </xsl:template> 

</xsl:stylesheet> 

然而，这是给我myname:Person下面的输出被复制：

<?xml version="1.0" encoding="UTF-8"?> 
<myname:Person xmlns:myname="http://www.myname.co.uk/def"> 
    <myname:Person> 
     <myname:attr1>some value</myname:attr1> 
     <myname:attr2>some value</myname:attr2> 
    </myname:Person> 
    <myname:FullName> 
     <myname:first_name>john</myname:first_name> 
     <myname:last_name>smith</myname:last_name> 
    </myname:FullName> 
</myname:Person> 

我做错了什么？

在此先感谢您的帮助。

Answer 1

其中一个<myname:Person>元素来自模板中的文字结果元素，另一个来自<xsl:copy>。如果你想

<?xml version="1.0" encoding="UTF-8"?> 
<myname:Person xmlns:myname="http://www.myname.co.uk/def"> 
    <myname:attr1>some value</myname:attr1> 
    <myname:attr2>some value</myname:attr2> 
    <myname:FullName> 
     <myname:first_name>john</myname:first_name> 
     <myname:last_name>smith</myname:last_name> 
    </myname:FullName> 
</myname:Person> 

后来干脆离开了<xsl:copy>，即

<xsl:template match="myname:Person"> 
    <myname:Person> 
     <xsl:apply-templates select="@*|node()[local-name() != 'first_name' and local-name() != 'Person' and local-name() != 'last_name']"/> 
     <myname:FullName> 
      <xsl:apply-templates select="myname:first_name | myname:last_name"/> 
     </myname:FullName> 
    </myname:Person> 
</xsl:template> 

或可替换地离开了明确<myname:Person>：

<xsl:template match="myname:Person"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()[local-name() != 'first_name' and local-name() != 'Person' and local-name() != 'last_name']"/> 
     <myname:FullName> 
      <xsl:apply-templates select="myname:first_name | myname:last_name"/> 
     </myname:FullName> 
    </xsl:copy> 
</xsl:template>