我们来回顾一下为cudaMemcpy3D
的文件说:
程度字段定义 元素的转移区域的尺寸。如果CUDA阵列参与复制的程度是在该数组的元素来定义 。如果没有CUDA数组是 参与复制然后的区段在 无符号字符的元素来定义。
同样地,对于cudaMalloc3DArray
注释的文档:
所有值均以元素指定
所以,你需要形成要呼叫的程度需要有在元素的第一个维度(因为cudaMemcpy3D
中的一个分配是一个数组)。
但是,您的代码中可能有其他问题,因为您正在使用cudaMalloc
分配线性内存来源d_volumeMem
。 cudaMemcpy3D
预计线性源存储器已被分配为兼容音调。您的代码只是使用尺寸
SIZE_X*SIZE_Y*SIZE_Z*sizeof(float)
现在它可能是你所选择的尺寸产生了您正在使用的硬件兼容的间距的线性分配,但不保证它会这么做。我建议使用cudaMalloc3D
来分配线性源内存。这在你小的代码段建立了一个扩大示范可能是这样的:
#include <cstdio>
typedef float VolumeType;
const size_t SIZE_X = 8;
const size_t SIZE_Y = 8;
const size_t SIZE_Z = 8;
const size_t width = sizeof(VolumeType) * SIZE_X;
texture<VolumeType, cudaTextureType3D, cudaReadModeElementType> tex;
__global__ void testKernel(VolumeType * output, int dimx, int dimy, int dimz)
{
int tidx = threadIdx.x + blockIdx.x * blockDim.x;
int tidy = threadIdx.y + blockIdx.y * blockDim.y;
int tidz = threadIdx.z + blockIdx.z * blockDim.z;
float x = float(tidx)+0.5f;
float y = float(tidy)+0.5f;
float z = float(tidz)+0.5f;
size_t oidx = tidx + tidy*dimx + tidz*dimx*dimy;
output[oidx] = tex3D(tex, x, y, z);
}
inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true)
{
if (code != cudaSuccess)
{
fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
if (abort) exit(code);
}
}
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
template<typename T>
void init(char * devPtr, size_t pitch, int width, int height, int depth)
{
size_t slicePitch = pitch * height;
int v = 0;
for (int z = 0; z < depth; ++z) {
char * slice = devPtr + z * slicePitch;
for (int y = 0; y < height; ++y) {
T * row = (T *)(slice + y * pitch);
for (int x = 0; x < width; ++x) {
row[x] = T(v++);
}
}
}
}
int main(void)
{
VolumeType *h_volumeMem, *d_output, *h_output;
cudaExtent volumeSizeBytes = make_cudaExtent(width, SIZE_Y, SIZE_Z);
cudaPitchedPtr d_volumeMem;
gpuErrchk(cudaMalloc3D(&d_volumeMem, volumeSizeBytes));
size_t size = d_volumeMem.pitch * SIZE_Y * SIZE_Z;
h_volumeMem = (VolumeType *)malloc(size);
init<VolumeType>((char *)h_volumeMem, d_volumeMem.pitch, SIZE_X, SIZE_Y, SIZE_Z);
gpuErrchk(cudaMemcpy(d_volumeMem.ptr, h_volumeMem, size, cudaMemcpyHostToDevice));
cudaArray * d_volumeArray;
cudaChannelFormatDesc channelDesc = cudaCreateChannelDesc<VolumeType>();
cudaExtent volumeSize = make_cudaExtent(SIZE_X, SIZE_Y, SIZE_Z);
gpuErrchk(cudaMalloc3DArray(&d_volumeArray, &channelDesc, volumeSize));
cudaMemcpy3DParms copyParams = {0};
copyParams.srcPtr = d_volumeMem;
copyParams.dstArray = d_volumeArray;
copyParams.extent = volumeSize;
copyParams.kind = cudaMemcpyDeviceToDevice;
gpuErrchk(cudaMemcpy3D(©Params));
tex.normalized = false;
tex.filterMode = cudaFilterModeLinear;
tex.addressMode[0] = cudaAddressModeWrap;
tex.addressMode[1] = cudaAddressModeWrap;
tex.addressMode[2] = cudaAddressModeWrap;
gpuErrchk(cudaBindTextureToArray(tex, d_volumeArray, channelDesc));
size_t osize = 64 * sizeof(VolumeType);
gpuErrchk(cudaMalloc((void**)&d_output, osize));
testKernel<<<1,dim3(4,4,4)>>>(d_output,4,4,4);
gpuErrchk(cudaPeekAtLastError());
h_output = (VolumeType *)malloc(osize);
gpuErrchk(cudaMemcpy(h_output, d_output, osize, cudaMemcpyDeviceToHost));
for(int i=0; i<64; i++)
fprintf(stdout, "%d %f\n", i, h_output[i]);
return 0;
}
您可以自己确认的纹理输出的主机上读取原始的源内存匹配。
我很好奇你怎么写“实际上,我的程序运行良好,但我不确定结果是否正确”。这不是矛盾吗?你怎么能不确定结果是“正确的”?你当然知道正确的结果应该是什么? – talonmies
我的意思是程序可以运行并输出结果,但我不确定结果是否正确。事实上,我需要一个3D纹理来绘制图片,但我不知道图片应该是什么。关键是我将数据复制到我上面描述的3D数组中。如果不对,我认为结果可能会有一些错误。 – TonyLic