如何使用make_cudaExtent正确定义cudaExtent？

Question

我想有一个CUDA 3D float数组，这里是我的代码：

#define SIZE_X 128 //numbers in elements 
#define SIZE_Y 128 
#define SIZE_Z 128 
typedef float VolumeType; 
cudaExtent volumeSize = make_cudaExtent(SIZE_X, SIZE_Y, SIZE_Z); //The first argument should be SIZE_X*sizeof(VolumeType)?? 

float *d_volumeMem; 
cutilSafeCall(cudaMalloc((void**)&d_volumeMem, SIZE_X*SIZE_Y*SIZE_Z*sizeof(float))); 

.....//assign value to d_volumeMem in GPU 

cudaArray *d_volumeArray = 0; 
cudaChannelFormatDesc channelDesc = cudaCreateChannelDesc<VolumeType>(); 
cutilSafeCall(cudaMalloc3DArray(&d_volumeArray, &channelDesc, volumeSize)); 
cudaMemcpy3DParms copyParams = {0}; 
copyParams.srcPtr = make_cudaPitchedPtr((void*)d_volumeMem, SIZE_X*sizeof(VolumeType), SIZE_X, SIZE_Y); // 
copyParams.dstArray = d_volumeArray; 
copyParams.extent = volumeSize; 
copyParams.kin = cudaMemcpyDeviceToDevice; 
cutilSafeCall(cudaMemcpy3D(&copyParams)); 

其实，我的程序运行良好。但我不确定结果是否正确。这里是我的问题，在CUDA liberay，它表示make_cudaExtent的第一个参数是“以字节为单位宽度”和另外两个是在元素的高度和深度。所以我觉得在我上面的代码，第五个行应该是

cudaExtent volumeSize = make_cudaExtent(SIZE_X*sizeof(VolumeType), SIZE_Y, SIZE_Z); 

但这种方式，就在cutilSafeCall（cudaMemcpy3D（& copyParams））错误“无效的参数”;为什么？

而另一难题是strcut cudaExtent，作为CUDA库所述，其组分宽度“指的是阵列中的存储器的情况下，以字节为单位指的线性存储器时宽度中的元素”代表。所以我想在我的代码中引用volumeSize.width时，它应该是元素中的数字。然而，如果使用

cudaExtent volumeSize = make_cudaExtent(SIZE_X*sizeof(VolumeType), SIZE_Y, SIZE_Z); 

的volumeSize.width将SIZE_X *的sizeof（VolumeType）（128 * 4），即在元件中的字节数数代替。

在许多CUDA SDK，他们使用碳作为VolumeType，所以他们只是用SIZE_X作为make_cudaExtent第一个参数。但是我的是浮动的，所以，任何人都可以告诉我，如果我需要使用它来创建3D数组，那么创建cudaExtent的正确方法是什么？非常感谢！

Answer 1

我们来回顾一下为cudaMemcpy3D的文件说：

程度字段定义 元素的转移区域的尺寸。如果CUDA阵列参与复制的程度是在该数组的元素来定义 。如果没有CUDA数组是 参与复制然后的区段在 无符号字符的元素来定义。

同样地，对于cudaMalloc3DArray注释的文档：

所有值均以元素指定

所以，你需要形成要呼叫的程度需要有在元素的第一个维度（因为cudaMemcpy3D中的一个分配是一个数组）。

但是，您的代码中可能有其他问题，因为您正在使用cudaMalloc分配线性内存来源d_volumeMem。 cudaMemcpy3D预计线性源存储器已被分配为兼容音调。您的代码只是使用尺寸

SIZE_X*SIZE_Y*SIZE_Z*sizeof(float) 

现在它可能是你所选择的尺寸产生了您正在使用的硬件兼容的间距的线性分配，但不保证它会这么做。我建议使用cudaMalloc3D来分配线性源内存。这在你小的代码段建立了一个扩大示范可能是这样的：

#include <cstdio> 

typedef float VolumeType; 

const size_t SIZE_X = 8; 
const size_t SIZE_Y = 8; 
const size_t SIZE_Z = 8; 
const size_t width = sizeof(VolumeType) * SIZE_X; 

texture<VolumeType, cudaTextureType3D, cudaReadModeElementType> tex; 

__global__ void testKernel(VolumeType * output, int dimx, int dimy, int dimz) 
{ 
    int tidx = threadIdx.x + blockIdx.x * blockDim.x; 
    int tidy = threadIdx.y + blockIdx.y * blockDim.y; 
    int tidz = threadIdx.z + blockIdx.z * blockDim.z; 

    float x = float(tidx)+0.5f; 
    float y = float(tidy)+0.5f; 
    float z = float(tidz)+0.5f; 

    size_t oidx = tidx + tidy*dimx + tidz*dimx*dimy; 
    output[oidx] = tex3D(tex, x, y, z); 
} 

inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true) 
{ 
    if (code != cudaSuccess) 
    { 
     fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line); 
     if (abort) exit(code); 
    } 
} 

#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); } 

template<typename T> 
void init(char * devPtr, size_t pitch, int width, int height, int depth) 
{ 
    size_t slicePitch = pitch * height; 
    int v = 0; 
    for (int z = 0; z < depth; ++z) { 
     char * slice = devPtr + z * slicePitch; 
     for (int y = 0; y < height; ++y) { 
      T * row = (T *)(slice + y * pitch); 
      for (int x = 0; x < width; ++x) { 
       row[x] = T(v++); 
      } 
     } 
    } 
} 

int main(void) 
{ 
    VolumeType *h_volumeMem, *d_output, *h_output; 

    cudaExtent volumeSizeBytes = make_cudaExtent(width, SIZE_Y, SIZE_Z); 
    cudaPitchedPtr d_volumeMem; 
    gpuErrchk(cudaMalloc3D(&d_volumeMem, volumeSizeBytes)); 

    size_t size = d_volumeMem.pitch * SIZE_Y * SIZE_Z; 
    h_volumeMem = (VolumeType *)malloc(size); 
    init<VolumeType>((char *)h_volumeMem, d_volumeMem.pitch, SIZE_X, SIZE_Y, SIZE_Z); 
    gpuErrchk(cudaMemcpy(d_volumeMem.ptr, h_volumeMem, size, cudaMemcpyHostToDevice)); 

    cudaArray * d_volumeArray; 
    cudaChannelFormatDesc channelDesc = cudaCreateChannelDesc<VolumeType>(); 
    cudaExtent volumeSize = make_cudaExtent(SIZE_X, SIZE_Y, SIZE_Z); 
    gpuErrchk(cudaMalloc3DArray(&d_volumeArray, &channelDesc, volumeSize)); 

    cudaMemcpy3DParms copyParams = {0}; 
    copyParams.srcPtr = d_volumeMem; 
    copyParams.dstArray = d_volumeArray; 
    copyParams.extent = volumeSize; 
    copyParams.kind = cudaMemcpyDeviceToDevice; 
    gpuErrchk(cudaMemcpy3D(&copyParams)); 

    tex.normalized = false;      
    tex.filterMode = cudaFilterModeLinear;  
    tex.addressMode[0] = cudaAddressModeWrap; 
    tex.addressMode[1] = cudaAddressModeWrap; 
    tex.addressMode[2] = cudaAddressModeWrap; 
    gpuErrchk(cudaBindTextureToArray(tex, d_volumeArray, channelDesc)); 

    size_t osize = 64 * sizeof(VolumeType); 
    gpuErrchk(cudaMalloc((void**)&d_output, osize)); 

    testKernel<<<1,dim3(4,4,4)>>>(d_output,4,4,4); 
    gpuErrchk(cudaPeekAtLastError()); 

    h_output = (VolumeType *)malloc(osize); 
    gpuErrchk(cudaMemcpy(h_output, d_output, osize, cudaMemcpyDeviceToHost)); 

    for(int i=0; i<64; i++) 
     fprintf(stdout, "%d %f\n", i, h_output[i]); 

    return 0; 
} 

您可以自己确认的纹理输出的主机上读取原始的源内存匹配。