AS2全屏仅在舞台上的视频窗口

Question

我已经搜索了高和低的答案。我使用AS2而不是AS3，我知道有几种方法可以全屏显示视频/音频/文本聊天SWF，但是有什么方法可以在Flash文件中创建一个仅用于全屏显示视频窗口mc的按钮？如果我正常显示全屏，它会显示文本和所有我想显示的全屏单击时显示的视频窗口。我不知道如何做到这一点。任何帮助都会很棒。如果答案是在这个网站或网上，我不知道我是如何错过它的，因为我一直在寻找大约3周没有运气。如果是，请接受我的道歉。在此先感谢所有的火箭科学家:)

Answer 1

要做你想做的事情，你可以做正常的全屏和设置你的视频尺寸为Stage.width和Stage.height，当然不要忘记设置深度也。

就拿这个例子中，你可以在网上here看到：

// don't forget to set the Stage.scaleMode and Stage.align 
Stage.scaleMode = 'showAll'; // noBorder, exactFit, noScale 
Stage.align = 'T'; // top center 

// boolean to indicate if we do the fullscreen of the video element 
var video_is_fullscreen:Boolean = false; 
var server:String = null; 
var stream = 'http://stream.flowplayer.org/flowplayer-700.mp4'; 

var nc:NetConnection = new NetConnection(); 
    nc.connect(server); 
var ns:NetStream = new NetStream(nc); 
    ns.play(stream); 

    // we use a Video element inside a MovieClip to set the object depth later 
    video_player.video.attachVideo(ns); 
    video_player.video.smoothing = true; 

    // just to disable sound 
    video_player.attachAudio(ns); 
    var audio:Sound = new Sound(video_player); 
     audio.setVolume(0); 

// toggle play/pause video 
video_player.onPress = function(){ 
    ns.pause(); 
} 

// set stage fullscreen mode 
btn_fullscreen.onPress = function(){ 
    full_screen(); 
} 

// set video element fullscreen mode 
btn_fullscreen_video.onPress = function(){ 
    video_is_fullscreen = true; 
    full_screen(); 
} 
function full_screen(){ 
    Stage.displayState = Stage.displayState == 'normal' ? 'fullScreen' : 'normal'; 
} 

// add stage fullscreen event listener 
var event_listener:Object = new Object(); 
Stage.addListener(event_listener); 
event_listener.onFullScreen = function(fullscreen_active:Boolean){ 
    if(video_is_fullscreen){  
     if(fullscreen_active){ 
      // set our video element fullscreen mode 
      video_player._x = video_player._y = 0; 
      video_player._width = Stage.width; 
      video_player._height = Stage.height; 
     } else { 
      // set our video element to it's normal mode 
      video_player._x = 10; 
      video_player._y = 30; 
      video_player._width = 160; 
      video_player._height = 120; 
      video_is_fullscreen = false; 
     }  
    } else { 
     video_is_fullscreen = false; 
    } 
} 

// set depths of all stage elements 
function set_depths():Void { 
    image.swapDepths(2); 
    txt.swapDepths(4); 
    video_player.swapDepths(8); 
    btn_fullscreen.swapDepths(6); 
    btn_fullscreen_video.swapDepths(10); 
} 

set_depths(); 

当然这一点仅仅是一个例子向您展示的方式做一个全屏的视频，您就能够改善它，它适应您的需求。

希望所有可以帮助你。