CMake - 如何链接到我已经与我的项目打包的外部库？

Question

如何链接到我的项目中包含的外部库？

这里是我的项目是如何设置：

我有一个名为app文件夹，这是我在那里坐的main.cpp。

C:\Raph\src\App 

main.cpp 

我也有一个名为“ExternalLibrary”文件夹，这正是我所捆绑的Qt库，我需要在我的项目中使用：

C:\Raph\src\ExternalLibrary\Platform\Windows\Qt5.6\VS2013_64bit 

它包含3个文件夹：

**bin** 
    moc.exe 
    rcc.exe 
    uic.exe 
    ...... 
    bunch of Qt dll files 

**include** 
    bunch of Qt header files 

**lib** 
    bunch of Qt lib files 

我需要安装的CMake做三件事情：

1. 动态链接到我已经打包在“ExternalLibrary”中的Qt库。

2. 每当我在项目中添加Qt类或资源时，自动执行moc.exe，uic.exe，rcc.exe。我也不需要任何 生成的moc_myClassname.cpp显示在项目中。

3. 我希望所有的Qt dll最终都放在可执行文件所在的bin文件夹中。例如：

   C：\拉斐\建立\拉斐\的Windows \ 64 \调试\ BIN

   Raph.exe +所有必要的Qt的Dll

Answer 1

（1）你可以找到Qt库采用以下方式：

find_package(Qt5Core [...] 5.6 REQUIRED) 
add_executable(someExe file1.cpp) 
target_link_libraries(someExe Qt5::Core) 

请注意，您应该保留Qt的原始目录结构，也包含Qt cmake脚本，例如lib/cmake/Qt5/Qt5Config.cmake

如果你想有一个特定的目录将包括Qt的搜索时，你可以做（​​您搜索的Qt前）：

set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} "./your/path") 

例如，这可以是你提供的目录。

（2）您可以使用cmake的automoc功能。只需添加

set(CMAKE_AUTOMOC ON) 
set(CMAKE_INCLUDE_CURRENT_DIR ON) 

在您的cmake脚本的开头。 CMake也支持AUTOUIC和AUTORCC。我还没有尝试过，但可能的工作类似。 （3）您可以将自定义目标添加到您的项目中，以复制dll。当你建立这个目标时，所有的dll都会被复制。您可以从Qt查找脚本定义的目标（例如Qt5::Core）获取dll的路径。

get_target_property(LOC_R Qt5::Core LOCATION_RELEASE) 
get_target_property(LOC_D Qt5::Core LOCATION_DEBUG) 

但是，您还应该扫描这些目标的依赖性（他们依赖的其他dll）。你可以写，扫描为correspondig的dll目标的整个列表，并将它们添加到列表中选择宏，让我们把这些RELEASE_DLLS和DEBUG_DLLS：

macro(copydlls RELEASE_DLLS DEBUG_DLLS MODULELIST) 
    foreach(ELEMENT ${${MODULELIST}}) 
     get_target_property(LOC_R ${ELEMENT} LOCATION_RELEASE) 
     get_target_property(LOC_D ${ELEMENT} LOCATION_DEBUG) 
     list(APPEND ${RELEASE_DLLS} ${LOC_R}) 
     list(APPEND ${DEBUG_DLLS} ${LOC_D}) 


     get_target_property(DEPENDENCIES_RELEASE ${ELEMENT} IMPORTED_LINK_DEPENDENT_LIBRARIES_RELEASE) 
     foreach(DEPENDENCY ${DEPENDENCIES_RELEASE}) 
      if(TARGET ${DEPENDENCY}) 
       get_target_property(LOC_R ${DEPENDENCY} LOCATION_RELEASE) 
       if(${LOC_R} MATCHES ".dll$") 
        list(APPEND ${RELEASE_DLLS} ${LOC_R}) 
       endif() 
      endif() 
     endforeach()  

     get_target_property(DEPENDENCIES_DEBUG ${ELEMENT} IMPORTED_LINK_DEPENDENT_LIBRARIES_DEBUG) 
     foreach(DEPENDENCY ${DEPENDENCIES_DEBUG}) 
      if(TARGET ${DEPENDENCY}) 
       get_target_property(LOC_D ${DEPENDENCY} LOCATION_DEBUG) 
       if(${LOC_D} MATCHES ".dll$") 
        list(APPEND ${DEBUG_DLLS} ${LOC_D}) 
       endif()   
      endif() 
     endforeach()  

     get_target_property(DEPENDENCIES_RELEASE ${ELEMENT} IMPORTED_LINK_INTERFACE_LIBRARIES_RELEASE) 
     foreach(DEPENDENCY ${DEPENDENCIES_RELEASE}) 
      if(TARGET ${DEPENDENCY}) 
       get_target_property(LOC_R ${DEPENDENCY} LOCATION_RELEASE) 
       if(${LOC_R} MATCHES ".dll$") 
        list(APPEND ${RELEASE_DLLS} ${LOC_R}) 
       endif() 
      endif() 
     endforeach()  

     get_target_property(DEPENDENCIES_DEBUG ${ELEMENT} IMPORTED_LINK_INTERFACE_LIBRARIES_DEBUG) 
     foreach(DEPENDENCY ${DEPENDENCIES_DEBUG}) 
      if(TARGET ${DEPENDENCY}) 
       get_target_property(LOC_D ${DEPENDENCY} LOCATION_DEBUG) 
       if(${LOC_D} MATCHES ".dll$") 
        list(APPEND ${DEBUG_DLLS} ${LOC_D}) 
       endif() 
      endif() 
     endforeach() 

    endforeach() 
endmacro() 

然后，你可以得到所有的Qt的dll文件列表中，由调用这个宏有：

IF(MSVC) 
    set(QT_MODULES "Qt5::Core" "Qt5::Gui" "Qt5::Widgets") 
    set(RELEASE_DLLS) 
    set(DEBUG_DLLS) 
    copydlls(RELEASE_DLLS DEBUG_DLLS QT_MODULES)  
ENDIF(MSVC) 

当你检索到的信息，您可以创建自定义目标下列方式。假设您的列表中有您的所有dll路径RELEASE_DLLS和DEBUG_DLLS，并且您的可执行文件名称为TARGETS中的列表。然后，你可以做这样的事情：

if(MSVC) 

    set(COPY_COMMAND_RELEASE "-E copy_if_different ") 
    set(COPY_COMMAND_DEBUG "-E copy_if_different ") 

    list(REMOVE_DUPLICATES RELEASE_DLLS) 
    list(REMOVE_DUPLICATES DEBUG_DLLS) 

    foreach(DLL ${RELEASE_DLLS}) 
     string(CONCAT COPY_COMMAND_RELEASE "${COPY_COMMAND_RELEASE} \"${DLL}\" ") 
    endforeach() 
    foreach(DLL ${DEBUG_DLLS}) 
     string(CONCAT COPY_COMMAND_DEBUG "${COPY_COMMAND_DEBUG} \"${DLL}\" ") 
    endforeach() 

    string(CONCAT COPY_COMMAND_RELEASE ${COPY_COMMAND_RELEASE} "\"${CMAKE_CURRENT_BINARY_DIR}/Release\" ") 
    string(CONCAT COPY_COMMAND_DEBUG ${COPY_COMMAND_DEBUG} "\"${CMAKE_CURRENT_BINARY_DIR}/Debug\" ") 

    add_custom_target(COPY_DLLS) 

    foreach(EXECUTABLE ${TARGETS}) 
     add_custom_command(TARGET COPY_DLLS PRE_BUILD COMMAND ${CMAKE_COMMAND} ${COPY_COMMAND_RELEASE} COMMENT "Copying dlls to executable directory...") 
     add_custom_command(TARGET COPY_DLLS PRE_BUILD COMMAND ${CMAKE_COMMAND} ${COPY_COMMAND_DEBUG} COMMENT "Copying dlls to executable directory...") 
    endforeach() 

endif() 

如果你想要这个目标每隔您的其他目标之一是建立执行时间，你可以这样做：

foreach(EXECUTABLE ${TARGETS}) 
    add_dependencies(${EXECUTABLE} COPY_DLLS) 
endforeach() 

不要foget你还必须将它添加到复制DLL目标从plugins的platforms目录复制到你的可执行文件夹，例如：

add_custom_command(TARGET COPY_DLLS PRE_BUILD 
    COMMAND ${CMAKE_COMMAND} -E copy_directory ${PATH_QT_ROOT}/plugins/platforms ${CMAKE_CURRENT_BINARY_DIR}/Debug/platforms 
    COMMAND ${CMAKE_COMMAND} -E copy_directory ${PATH_QT_ROOT}/plugins/platforms ${CMAKE_CURRENT_BINARY_DIR}/Release/platforms 
    COMMENT "Copying Qt platforms to executable directory...")