XSL的for-each空间分隔的属性值

我的研究项目，我在XML这个文件/ TEIXSL的for-each空间分隔的属性值

<TEI xmlns="http://www.tei-c.org/ns/1.0" > 
<body> 
    <div> 
     <p> 
      <span target="#" type="passage" ana="Tag957 Tag874"> 
       <span target="#" ana=""/> 
      </span> 
      <seg><date when="1980-01-01" type="date_seg"/>blabla blabla 
       blabla blablablabla blablablabla blablablabla blablablabla bl 
      </seg> 
      <span target="#" type="passage" ana="Tag1657 "> 
       <span target="#" ana=""/> 
      </span> 
      <seg><date from="1980-01-03" to="1980-01-05" type="date_seg"/>blabla 
      </seg> 
     </p> 
    </div> 
</body> 
</TEI>

我需要提取包含在跨越每个标签/ @语录：日期和以下节点seg的字符串长度。如果我们计算日期属性@from或@to，我只需要@from的值。我需要看起来像：

Tag957;1980-01-01;88 
Tag874;1980-01-01;88 
Tag1657;1980-01-03;11

我想这一点，但我不知道怎么换每次在一个时间applyed一个属性值表达

<xsl:template match="tei:p"> 
     <xsl:for-each select="tei:span"> 
       <xsl:value-of select="./@ana"/> 
       <xsl:text>;</xsl:text> 
      <xsl:if test="following-sibling::tei:seg/tei:date/@from or following-sibling::tei:seg/tei:date/@to"> 
       <xsl:value-of select="following-sibling::tei:seg/tei:date/@from"/> 
      </xsl:if> 
      <xsl:if test="following-sibling::tei:seg/tei:date/@when"> 
       <xsl:value-of select="following-sibling::tei:seg/tei:date/@when"/> 
      </xsl:if> 
       <xsl:text>;</xsl:text> 
       <xsl:value-of select="string-length(following-sibling::tei:seg)"/> 
       <xsl:text>;</xsl:text> 
       <xsl:value-of select="$newLine"/> 
     </xsl:for-each> 
</xsl:template>

来源

2017-01-26 r.let

哪个XSLT处理器，XSLT版本做你用/你可以用吗？ –

我在Oxygen软件中使用XSLT处理器，我选择的是Saxon-HE9.6.0.7 –

使用XSLT 2.0，您可以使用tokenize识别属性值不同的值，那么你可以在http://xsltransform.net/jz1PuPL重写代码为

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xpath-default-namespace="http://www.tei-c.org/ns/1.0"> 
    <xsl:template match="p"> 
     <xsl:for-each select="span"> 
      <xsl:variable name="span" select="."/> 
      <xsl:for-each select="tokenize(@ana, '\s+')[normalize-space()]"> 
       <xsl:value-of select="."/> 
       <xsl:text>;</xsl:text> 
       <xsl:if test="$span/following-sibling::seg[1]/date/@from or $span/following-sibling::seg[1]/date/@to"> 
       <xsl:value-of select="$span/following-sibling::seg[1]/date/@from"/> 
       </xsl:if> 
       <xsl:if test="$span/following-sibling::seg/date/@when"> 
       <xsl:value-of select="$span/following-sibling::seg/date/@when"/> 
       </xsl:if> 
       <xsl:text>;</xsl:text> 
       <xsl:value-of select="string-length($span/following-sibling::seg[1])"/> 
       <xsl:text>;</xsl:text> 
       <xsl:value-of select="'&#10;'"/> 
      </xsl:for-each>  
     </xsl:for-each> 
    </xsl:template> 
</xsl:transform>

在线。

来源

2017-01-26 13:02:17

谢谢，它在我给的XML上运行良好。我在我的其他文件上测试了它，并且必须在第二个xsl中添加seg [1]：如果导致它检索所有其他兄弟的日期seg –

你对于span元素只做了单环。这不够。

实际上，对于每个这样的span你必须：

阅读ana属性。
使用空格（如果可以的话，使用XSLT 2.0，它具有此功能）令其变形。

对于每个结果令牌（不是为@ana整个价值），你必须进行内部for-each循环：

查找只有第一以下seg兄弟及其子date元素： select="following-sibling::tei:seg[1]/tei:date"（注意，我加了[1]）。
检查它是否包含必需的属性（from,to或when）。

如果确实如此，那么：

打印从目前ana属性提取当前令牌。
根据您的需要打印需要的日期（从当前的date元素开始）。
打印要打印的东西的其余部分。

这只是一个草图，我省略了保留两个循环中的当前值在各个变量中的细节。

我希望它能帮助您达到最终结果。

来源

2017-01-26 12:58:58

XSLT-1。0

我创建了一个递归模板来标记化ana属性中的值，并为每个跨度调用它。我不得不在第8行添加一个空格为模板的工作： <xsl:with-param name="remaining-ana-val" select="substring-after(concat(./@ana,' '),' ')"/>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"> 
    <xsl:output method="text" omit-xml-declaration="yes" encoding="UTF-8"/> 
    <xsl:strip-space elements="*"/> 
    <xsl:template match="tei:p"> 
     <xsl:for-each select="tei:span"> 
      <xsl:call-template name="recurse_ana"> 
       <xsl:with-param name="ana_val" select="substring-before(./@ana,' ')"/> 
       <xsl:with-param name="remaining-ana-val" select="substring-after(concat(./@ana,' '),' ')"/> 
       <xsl:with-param name="seg" select="following-sibling::tei:seg[1]"/> 
      </xsl:call-template> 
     </xsl:for-each> 
    </xsl:template> 
    <xsl:template name="recurse_ana"> 
     <xsl:param name="ana_val"/> 
     <xsl:param name="remaining-ana-val"/> 
     <xsl:param name="seg"/> 
     <xsl:if test="string-length($ana_val) > 0"><xsl:value-of select="$ana_val"/> 
      <xsl:value-of select="';'"/> 
      <xsl:value-of select="$seg/tei:date/(@when|@from)"/> 
      <xsl:value-of select="';'"/> 
      <xsl:value-of select="string-length($seg)"/> 
      <xsl:value-of select="'&#x0D;'"/> 
      <xsl:call-template name="recurse_ana"> 
       <xsl:with-param name="ana_val" select="substring-before($remaining-ana-val,' ')"/> 
       <xsl:with-param name="remaining-ana-val" select="substring-after($remaining-ana-val,' ')"/> 
       <xsl:with-param name="seg" select="$seg"/> 
      </xsl:call-template> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet>

输出：

Tag957;1980-01-01;105 
Tag874;1980-01-01;105 
Tag1657;1980-01-03;19

在线链接：分别http://xsltransform.net/gWEamLJ/2

来源

2017-01-26 13:30:31 Madeyedexter

感谢您的建议。我在其他文件上测试过它，但它似乎只处理@ana中具有多个值的跨度，而不是仅具有一个值的跨度。奇怪的是:-) –

@ r.let样例XML中的第二个跨度在'ana'属性内有额外的空间。我利用它来标记属性值。也许其他'span'没有这个额外的属性，因此被排除在外。 – Madeyedexter

XSL的for-each空间分隔的属性值

回答

相关问题