长度有序的子集？

Question

我试图做一个代码，以的顺序生成集合的所有子集。 也就是说，调用subset([1,2,3], X)应该产生

X = []; 
X = [1]; 
X = [2]; 
X = [3]; 
X = [1,2]; 
X = [1,3]; 
X = [2,3]; 
X = [1,2,3]. 

内部顺序并不那么重要，只有最小的子集列第一（即我不在乎[2,3] [1日前来，2]，只有1，[2]和[3]在[2,3]之前）。

-

到目前为止，我已经尝试了两种方法。首先，我试着自己做出这个谓词......

subset([], []). 
subset(List, []). 
subset(List, [N]) :- 
    member(N, List). 

subset(List, [N|Rest]) :- 
    !, 
    nth0(I, List, N), 
    findall(E, (nth0(J, List, E), J > I), NewList), 
    subset2(NewList, Rest). 

......但它甚至没有达到预期的效果。其次，我尝试制作powerset（使用this subset predicate）并使用list_to_ord_set/2进行排序，但是我也无法使其工作。

帮助？

Answer 1

我发现一个不那么完美的解决方案......它需要切割和一些内建

subset(Xs, Ys) :- 
    length(Xs, L), 
    between(0, L, N), 
    length(Ys, N), 
    assign(Xs, Ys). 

assign(_, []) :- !. 
assign([X|Xs], [X|Ys]) :- 
    assign(Xs, Ys). 
assign([_|Xs], Ys) :- 
    assign(Xs, Ys). 

由@Fatalize指出的那样，我们能够避免晋级，只是迫使在第一个参数的空列表1 ^子句：

assign([], []). 
assign([X|Xs], [X|Ys]) :- 
    assign(Xs, Ys). 
assign([_|Xs], Ys) :- 
    assign(Xs, Ys). 

我回避掉2^3 ^条款，从而“自然”订单仍然保持很好

Answer 2

也总是考虑使用DCG notation磨片n描述列表。

例如：

list_sublist(Ls0, Ls) :- 
     same_length(Ls0, Ls1), 
     append(Ls, _, Ls1), 
     phrase(sublist(Ls0), Ls). 

sublist([])  --> []. 
sublist([L|Ls]) --> ([] ; [L]), sublist(Ls). 

样品查询：

?- list_sublist([a,b,c], Ls). 
Ls = [] ; 
Ls = [c] ; 
Ls = [b] ; 
Ls = [a] ; 
Ls = [b, c] ; 
Ls = [a, c] ; 
Ls = [a, b] ; 
Ls = [a, b, c] ; 
false. 

又如：

?- list_sublist(Ls, [b,c]). 
Ls = [b, c] ; 
Ls = [_G511, b, c] ; 
Ls = [b, _G514, c] ; 
Ls = [b, c, _G517] ; 
etc. 

最常见的情况：

?- list_sublist(Xs, Ys). 
Xs = Ys, Ys = [] ; 
Xs = [_G513], 
Ys = [] ; 
Xs = Ys, Ys = [_G513] 
Xs = [_G513, _G516], 
Ys = [] ; 
etc.