如何从文本输出日期值

Question

所以我在我的专栏中混淆了日期信息。例如Jan预先计划2017年，Feb计划后2017年低等。

两件事总是一致的：几个月总是以3个字母开头。而一年来的4个数字（可以在任何地方。）

基本上，我需要他们在标准日期格式（例如2017年1月1日，2017年1月2日等）

Answer 1

首先转换您的字符串为日期值：

s = "Jan preplan-2017" 
TrueDate = DateValue("1 " & Left(s, 3) & " " & Right(s, 4)) 

然后 - 显示 - 格式要求：

ShowDate = Format(TrueDate, "d.m.yyyy") 

或者一气呵成：

ShowDate = Format(DateValue("1 " & Left(s, 3) & " " & Right(s, 4)), "d.m.yyyy") 

编辑：使用拆分创建的元素，这些循环的数组，并挑选一个是一个整数：

Year = Split("Feb-afterplan-2017-low", "-")(2) 

Answer 2

我不是辉煌与正则表达式那么无疑这可以改善。

作为一个工作表函数：

Public Function ConvertDate(sData As String) As Variant 
    Dim RE As Object, REMatches As Object 
    Dim Temp As String 

    Set RE = CreateObject("vbscript.regexp") 
    With RE 
     .MultiLine = False 
     .Global = False 
     .IgnoreCase = True 
     .Pattern = "\d{4}" 
    End With 

    Set REMatches = RE.Execute(sData) 
    If REMatches.Count > 0 Then 
     Temp = "1-" & Left(sData, 3) & "-" & REMatches(0) 
     ConvertDate = CDate(DateValue(Temp)) 
    Else 
     'Returns #VALUE error on no match. 
     ConvertDate = CVErr(xlValue) 
    End If 
End Function 

按引用传递日期和返回TRUE/FALSE：

Public Sub Test() 

    Dim MyDate As Date 

    If ConvertDate1("Jan preplan-2017", MyDate) Then 
     MsgBox "Date converted to " & Format(MyDate, "dd-mmm-yy"), vbOKOnly 
    Else 
     MsgBox "Date not converted.", vbOKOnly 
    End If 

End Sub 

Public Function ConvertDate1(sData As String, ByRef ReturnValue As Date) As Boolean 
    Dim RE As Object, REMatches As Object 
    Dim Temp As String 

    Set RE = CreateObject("vbscript.regexp") 
    With RE 
     .MultiLine = False 
     .Global = False 
     .IgnoreCase = True 
     .Pattern = "\d{4}" 
    End With 

    Set REMatches = RE.Execute(sData) 
    If REMatches.Count > 0 Then 
     Temp = "1-" & Left(sData, 3) & "-" & REMatches(0) 
     ReturnValue = CDate(DateValue(Temp)) 
     ConvertDate1 = True 
    Else 
     ConvertDate1 = False 
    End If 
End Function 

正则表达式，可以提高检查前三个字母是一个月...负荷可以做些改进，但你可以得到我希望的照片。