将基本ActionScript 2转换为ActionScript 3用于翻转动画

Question

所以，我想要做的事情应该很简单。这只是一个翻转动画，当用户将鼠标关闭时会反转。事情是，它在AS2中，但我认为要完成该项目，我将在AS3中使用它。任何人都可以提供一些意见上的转换这...

stop(); 

this.onEnterFrame = function(){ 
if(rewind == true){ 
prevFrame(); 
} 
} 

this.onRollOver = function(){ 
rewind = false; 
play(); 
} 

this.onRollOut = function(){ 
rewind = true; 
} 

this.onRelease = function(){ 
getURL("http://www.google.com","_blank"); 
} 

...到AS3？我会非常感激。

Answer 1

如果你的代码需要限制这些，你应该学会如何在AS3中完成它。

在这里，在AS3完全一样的事情

import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.net.navigateToURL; 
import flash.net.URLRequest; 

stop(); 
addEventListener(Event.ENTER_FRAME, onEnterFrame); 
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver); 
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut); 
addEventListener(MouseEvent.CLICK, onClick); 

var rewind:Boolean = false; 

function onEnterFrame(event:Event):void 
{ 
    if (rewind == true) { 
     prevFrame(); 
    } 
} 

function onMouseOver(event:MouseEvent):void 
{ 
    rewind = false; 
    play(); 
} 

function onMouseOut(event:MouseEvent):void 
{ 
    rewind = true; 
} 

function onClick(event:MouseEvent):void 
{ 
    navigateToURL(new URLRequest("http://www.google.com"),"_blank"); 
} 

请注意，而不是创建一个监听到的事件（翻滚例如）通过写this.onRollOver = function()，你确实有调用addEventListener（这是非常合乎逻辑），指定要侦听的事件并创建一个在捕获此事件时调用的函数。

也有在getURL另一个区别 - >navigateToURL，但我认为它:)

作为感谢你不需要任何进一步的解释，我真的很感谢你阅读这段代码，并尝试从中学习，而不是大致复制/粘贴。但是，嘿，你是免费的！