在数组中搜索字符串并返回AS3中的索引

Question

我想要搜索数组以查看它是否包含特定的字符串，然后获取结果的索引。

举例来说，如果我有：

array[0] = "dogs"; 
array[1] = "cats"; 
array[2] = "oranges"; 

我希望能够搜索“奥兰”，并获得2回。任何想法如何做到这一点？

Answer 1

你可以做这样的事情：

function findInArray(str:String):int { 
    for(var i:int = 0; i < array.length; i++){ 
     if(array[i] == str){ 
      trace("found it at index: " + i); 
      return i; 
     } 
    } 
    return -1; //If not found 
} 

然后只要你想找到这样称呼它：

findInArray("oranges"); // Returns 2 

要搜索词的一部分可以pontentially返回undesiderd结果更大的名单，但你可以做到以下几点：

function findInArrayPartially(str:String):int { 
    for(var i:int = 0; i < array.length; i++){ 
     if(array[i].indexOf(str) > -1){ 
      trace("found it at index: " + i); 
      return i; 
     } 
    } 
    return -1; //If not found 
} 

Answer 2

另一种方法：

var arr:Array = ["dogs", "cats", "oranges", "apples"]; 

function indexOfSubstring(array:Array, stringToFind:String):int 
{ 
    var answer:int = array.indexOf(stringToFind); 

    if (answer == -1) 
    { 
     var separator:String = "|"; 
     var arrayToString:String = array.join(separator); 
     var indexInString:int = arrayToString.indexOf(stringToFind); 

     if (indexInString != -1) 
     { 
      var shorterStr:String = arrayToString.substring(0, indexInString); 
      answer = shorterStr.split(separator).length - 1; 
     } 
    } 

    return answer; 
} 

trace(indexOfSubstring(arr, "oran")); // returns 2 
trace(indexOfSubstring(arr, "les")); // returns 3 
trace(indexOfSubstring(arr, "ts")); // returns 1 
trace(indexOfSubstring(arr, "broom")); // returns -1