Prolog的语法 - 使用功能导致

Question

我想对每一个结果进行求和运算：

combination(0,_,[]). 
combination(K,L,[X|Xs]) :- 
    K > 0, 
    el(X,L,R), 
    K1 is K-1, 
    combination(K1,R,Xs). 

el(X,[X|L],L). 
el(X,[_|L],R) :- el(X,L,R). 

例如，用户将进入is_sum_equal_10（[1,2,3,4,5,6 ，7]），结果将是真实的，如果任何排列的总和等于10.

我很努力把它放在一起，有人可以帮我定义is_sum_equal_10规则，每个规则使用组合规则排列？

Answer 1

好吧，写起来真的很容易，你只需要一个规则来说明一个特定的组合是否为10，然后另一个额外的一个通过不同大小的组合列表来计数（这是因为你用K写的组合方式，你在检查规则时需要减少）。

1 ?- [user]. 
|: combination(0,_,[]). 
|: combination(K,L,[X|Xs]) :- K > 0, 
|: el(X,L,R), K1 is K-1, combination(K1,R,Xs). 
|: el(X,[X|L],L). 
|: el(X,[_|L],R) :- el(X,L,R). 
|: 
|: totals_10([],10). 
|: totals_10([X|Xs],T) :- N is T+X, totals_10(Xs,N). 
|: 
|: is_comb_sum_equal_10(Numbers,_,R) :- combination(R,Numbers,C), totals_10(C,0). 
|: is_comb_sum_equal_10(Numbers,N,R) :- Rnext is R+1, Rnext =< N, 
|: is_comb_sum_equal_10(Numbers,N,Rnext). 
|: 
|: is_sum_equal_10(Numbers) :- length(Numbers,N), is_comb_sum_equal_10(Numbers,N,0). 
|: 
% user://1 compiled 0.13 sec, 1,824 bytes 
true. 

2 ?- is_sum_equal_10([2,3,5]). 
true . 

3 ?- is_sum_equal_10([2,235,124,3,3347,5,2373]). 
true . 

4 ?- is_sum_equal_10([2,235,124,3,3347,6,2373]). 
false. 

5 ?- is_sum_equal_10([1,1,1,1,1,-1,1,1,1,1,12]). 
false. 

6 ?- is_sum_equal_10([1,1,1,1,1,-1,1,1,1,1,11]). 
true ; 
false. 

既然你不关心实际的列表或有多大它是在is_sum_equal_10的事情，你可以总结的组合，你走，甚至更好，检查总和作为一项规则正确为基础案例。我认为如果你从基数中减去所需的总数来得到0，而不是在最后加上和检查你想要的值，那么这有点儿整洁。这给你一个非常简单的单一规则集来寻找一定的总和。

7 ?- [user]. 
|: is_subset_sum(0,[]). 
|: is_subset_sum(N,[_|Xs]) :- is_subset_sum(N,Xs). 
|: is_subset_sum(N,[X|Xs]) :- R is N-X, is_subset_sum(R,Xs). 
|: 
% user://2 compiled 0.03 sec, 540 bytes 
true. 

8 ?- is_subset_sum(10,[3,5,6]). 
false. 

9 ?- is_subset_sum(10,[123,4,1,77,3,2,34]). 
true . 

10 ?- is_subset_sum(11,[0,2,4,6,8,10,12,14,16,18,20,22]). 
false. 

这种方法当然更容易理解，并且效率更高。