如何在haskell中以二进制或十六进制打印整数文字？

Question

如何以二进制或十六进制打印haskell中的整数文字？

printBinary 5 => "0101" 

printHex 5 => "05" 

哪些库/函数允许这样做？

我遇到了Numeric模块及其showIntAtBase函数，但一直无法正确使用它。

> :t showIntAtBase 

showIntAtBase :: (Integral a) => a -> (Int -> Char) -> a -> String -> String 

Answer 1

数字模块包括几个functions for showing an Integral type在不同的基地，包括showIntAtBase。下面是使用的一些例子：

import Numeric (showHex, showIntAtBase) 
import Data.Char (intToDigit) 

putStrLn $ showHex 12 "" -- prints "c" 
putStrLn $ showIntAtBase 2 intToDigit 12 "" -- prints "1100" 

Answer 2

可以转换整数，像下面为二进制：在GHCI

decToBin x = reverse $ decToBin' x 
    where 
    decToBin' 0 = [] 
    decToBin' y = let (a,b) = quotRem y 2 in [b] ++ decToBin' a 

用法：

Prelude> decToBin 10 
[1,0,1,0] 

Answer 3

如果导入Numeric和Data.Char模块，你可以这样做：

showIntAtBase 2 intToDigit 10 "" => "1010" 
showIntAtBase 16 intToDigit 1023 "" => "3ff" 

这将为任何基地多达16个工作，因为这是所有intToDigit适用于。以上示例中额外的空字符串参数的原因是showIntAtBase返回类型为ShowS的函数，该函数将显示表示连接到现有字符串。

Answer 4

您也可以使用printf的包的printf到您的输出使用C风格的格式描述格式为：

import Text.Printf 

main = do 

    let i = 65535 :: Int 

    putStrLn $ printf "The value of %d in hex is: 0x%08x" i i 
    putStrLn $ printf "The html color code would be: #%06X" i 
    putStrLn $ printf "The value of %d in binary is: %b" i i 

输出：

的65535十六进制值是：0x0000ffff
的html颜色代码将是：＃00FFFF
二进制中的值65535是：1111111111111111

Answer 5

六角可以写与0x和二进制与0b前缀例如： -

> 0xff 
255 
>:set -XBinaryLiterals 
> 0b11 
3 

请注意二进制需要BinaryLiterals扩展。

Answer 6

你可以定义你自己喜欢的递归函数：

import Data.Char (digitToInt) 
import Data.Char (intToDigit) 

-- generic function from base to decimal 
toNum :: [Char] -> Int -> (Char -> Int) -> Int 
toNum [] base map = 0 
toNum s base map = base * toNum (init(s)) base map + map(last(s)) 

-- generic function from decimal to base k 
toKBaseNum :: Int -> Int -> (Int -> Char) -> [Char] 
toKBaseNum x base map | x < base = [map x] 
         | otherwise = toKBaseNum (x `div` base) base map ++ [map(x `mod` base)] 


-- mapping function for hex to decimal 
mapHexToDec :: Char -> Int 
mapHexToDec x | x == 'A' = 10 
       | x == 'B' = 11 
       | x == 'C' = 12 
       | x == 'D' = 13 
       | x == 'E' = 14 
       | x == 'F' = 15 
       | otherwise = digitToInt(x) :: Int 

-- map decimal to hex 
mapDecToHex :: Int -> Char 
mapDecToHex x | x < 10 = intToDigit(x) 
       | x == 10 = 'A' 
       | x == 11 = 'B' 
       | x == 12 = 'C' 
       | x == 13 = 'D' 
       | x == 14 = 'E' 
       | x == 15 = 'F' 

-- hex to decimal 
hexToDec :: String -> Int 
hexToDec [] = 0 
hexToDec s = toNum s 16 mapHexToDec 

-- binary to decimal 
binToDec :: String -> Int 
binToDec [] = 0 
binToDec s = toNum s 2 (\x -> if x == '0' then 0 else 1) 

-- decimal to binary 
decToBin :: Int -> String 
decToBin x = toKBaseNum x 2 (\x -> if x == 1 then '1' else '0') 

-- decimal to hex 
decToHex :: Int -> String 
decToHex x = toKBaseNum x 16 mapDecToHex 

说明： 正如你所看到的，toNum功能转换的k基于价值为十进制，使用给定的基础和映射函数。映射函数将特殊字符映射为十进制值（例如，A = 10，B = 11，...，十六进制）。对于二进制映射，您也可以使用像在binToDec中看到的lambda表达式。

而toKBaseVal函数是相反的，将小数转换为基于k的值。我们再次需要一个映射函数，它相反：从十进制到基于k值的对应特殊字符。

作为一个测试，你可以输入：

binToDec(decToBin 7) = 7 

假设你想从十进制转换为八进制：

-- decimal to octal 
decToOct :: Int -> String 
decToOct x = toKBaseNum x 8 (\x -> intToDigit(x)) 

同样，我只使用一个lambda表达式，因为映射很简单：只需诠释数字。

希望有帮助！好的编程！