Tcl匿名函数

Question

关于Tcl的纯理论问题。

正在关注this question我在想什么是在Tcl中实现匿名函数的最佳方式。

最终的结果应该被允许开发人员通过一个完整的PROC作为参数传递给anohter PROC：

do_something $data {proc {} {input} { 
    puts $input; 
}}; 

这将是类似于JavaScript的

do_something(data, function (input) { 
    alert(input); 
}); 

现在，当然，这不会工作OOTB。我在想这样的事情：

proc do_something {data anon_function} { 
    anon_run $anon_function $data 
} 
proc anon_run {proc args} { 
    set rand proc_[clock clicks]; 
    set script [lreplace $proc 1 1 $rand]; 
    uplevel 1 $script; 
    uplevel 1 [concat $rand $args]; 
    uplevel 1 rename $rand {}; //delete the created proc 
} 

这个工程。但我希望能得到一个更好的模式的建议，因为它不是很优雅，也不是真正使用酷的Tcl功能。主要我想摆脱手动呼叫anon_run。

Answer 1

在Tcl 8.5中，可以使用apply命令。 （！推荐）

proc do_something {data anon_function} { 
    apply $anon_function $data 
} 
do_something $data {{input} { 
    puts $input 
}} 

当然，如果你正在构建你的回调为命令前缀，那么你可以这样做：如果你使用8.4或之前

proc lambda {arguments body} { 
    # We'll do this properly and include the optional namespace 
    set ns [uplevel 1 namespace current] 
    return [list ::apply [list $arguments $body $ns]] 
} 

proc do_something {data command} { 
    {*}$command $data 
} 

do_something $data [lambda {input} { 
    puts $input 
}] 

，你需要的code from the Tcler's Wiki作为替代品，但请注意，这些解决方案仅在语义上相当（最好）;他们不是性能等效的。