Excel2011 - 查找并将多个值返回到一个单元格中按日期

我需要查找数字（重复出现）并返回数字旁边单元格的值，但仅限于同一日期。结果必须加入到同一个目标单元格中。Excel2011 - 查找并将多个值返回到一个单元格中按日期

我在Mac上使用Excel 2011。我没有Textjoin函数。但是，我找到了一个VBA UDF来查找并将多个值返回到一个单元格中。这是我使用的是什么：

Function MYVLOOKUP(pValue As String, pWorkRng As Range, pIndex As Long) 
'Update 20150310 
Dim rng As Range 
Dim xResult As String 
xResult = "" 
For Each rng In pWorkRng 
    If rng = pValue Then 
     xResult = xResult & " " & rng.Offset(0, pIndex - 1) 
    End If 
Next 
MYVLOOKUP = xResult 
End Function

它种工作，但只有在一个小区仰视值和另一列找到它。问题是我正在查找的值在不同的日期重复，我只想返回给定日期的值。我已经把它贴的什么，我想下面做一个样本：

Sample Spreadsheet

通知书“所需数据格式” G2被返回的数据职工1001数据库中的两个日期，但只有我希望它返回相关日期的数据，所以我试图将myvlookup UDF中的第一个变量设置为“E2：F2”，以便函数查找Date和Employee＃，但该函数似乎不起作用那样。

应显示在G2的值是“80011，80025”，应该显示在G3的值是“80011，80030”等

我希望我有更多的时间来想出解决办法我自己，但时间是至关重要的，所以我需要帮助。

来源

2017-06-23 Devil07

这里是模仿TEXTJOIN（）一个UDF：

Function TEXTJOIN(delim As String, skipblank As Boolean, arr) 
    Dim d As Long 
    Dim c As Long 
    Dim arr2() 
    Dim t As Long, y As Long 
    t = -1 
    y = -1 
    If TypeName(arr) = "Range" Then 
     arr2 = arr.Value 
    Else 
     arr2 = arr 
    End If 
    On Error Resume Next 
    t = UBound(arr2, 2) 
    y = UBound(arr2, 1) 
    On Error GoTo 0 

    If t >= 0 And y >= 0 Then 
     For c = LBound(arr2, 1) To UBound(arr2, 1) 
      For d = LBound(arr2, 1) To UBound(arr2, 2) 
       If arr2(c, d) <> "" Or Not skipblank Then 
        TEXTJOIN = TEXTJOIN & arr2(c, d) & delim 
       End If 
      Next d 
     Next c 
    Else 
     For c = LBound(arr2) To UBound(arr2) 
      If arr2(c) <> "" Or Not skipblank Then 
       TEXTJOIN = TEXTJOIN & arr2(c) & delim 
      End If 
     Next c 
    End If 
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
End Function

与您的数据，你会使用这个在数组公式：

=TEXTJOIN(" ",TRUE,IF((F2=B$2:B$14)*(A$2:A$14=E2),C$2:C$14,""))

作为它需要被证实数组公式在退出编辑模式时，按Ctrl-Shift-Enter而不是Enter。如果正确完成，Excel将在公式周围放置{}。

来源

2017-06-23 19:18:46

Excel2011 - 查找并将多个值返回到一个单元格中按日期

回答

相关问题