Nsis：在一个安装程序中更改标题栏

Question

我在一个安装程序中有两个安装： http://nsis.sourceforge.net/Two_installations_in_one_installer 如何自定义两个安装的标题栏（安装名称）？

Answer 1

NSIS是不是真的设计要做到这一点，所以你必须每次页面的变化进行手动设置：

!include MUI.nsh 
!include WinMessages.nsh 
Caption " " 

!define MUI_PAGE_CUSTOMFUNCTION_SHOW lic1 
!insertmacro MUI_PAGE_LICENSE "${__FILE__}" 
!define MUI_PAGE_CUSTOMFUNCTION_SHOW inst1 
!insertmacro MUI_PAGE_INSTFILES 
!define MUI_PAGE_CUSTOMFUNCTION_SHOW lic2 
!insertmacro MUI_PAGE_LICENSE "${__FILE__}" 
!define MUI_PAGE_CUSTOMFUNCTION_SHOW inst2 
!insertmacro MUI_PAGE_INSTFILES 
!insertmacro MUI_LANGUAGE English 

Function lic1 
SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Foo$(^LicenseSubCaption)" 
FunctionEnd 
Function inst1 
SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Foo$(^InstallingSubCaption)" 
FunctionEnd 
Function lic2 
SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Bar$(^LicenseSubCaption)" 
FunctionEnd 
Function inst2 
SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Bar$(^InstallingSubCaption)" 
FunctionEnd