XSLT转换，字符串连接

Question

我有下面的XML

<R N="14" MIME="application/pdf"> 
    <RK>7</RK> 
    <MT N="Abstract" 
     V="Lorem Ipsum is simply dummy text of the printing " /> 
    <MT N="Abstract1" 
    V="and typesetting industry. Lorem Ipsum has been the industry's standard "/> 
    <MT N="Author" V="Bernard Shaw;" /> 
    <MT N="Author1" V="Mark Twain" /> 
    <MT N="Abstract2" 
    V="dummy text ever since the 1500s, when an unknown printer took a galley"/> 
    <LANG>en</LANG> 
</R> 

当使用XSLT转换，我需要连接的摘要和作者字段，并显示它像

Abstract: Lorem Ipsum is simply dummy text of the printing and typesetting industry. Lorem Ipsum has been the industry's standard dummy text ever since the 1500s, when an unknown printer took a galley 

Author: Bernard Shaw;Mark Twain 

摘要， Abstract1，Abstract2可能以任何顺序出现在xml中。

我想使用类似以下，但卡在条件&串联串的时候摘要，Abstract1不会以相同的顺序

<xsl:template match="MT"> 
    <xsl:if test="(some generic condition to display Title)"> 
     <br/> 
     <span class="f"> 
      <xsl:value-of select="@N"/> 
     </span> 
    </xsl:if> 
    <xsl:value-of select="@V"/> 
</xsl:template> 

得到任何帮助出现。

Answer 1

该转化：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/"> 
    Abstract: <xsl:text/> 
    <xsl:for-each select="*/MT[starts-with(@N, 'Abstract')]"> 
     <xsl:value-of select="@V"/> 
    </xsl:for-each> 
    Author: <xsl:text/> 
    <xsl:for-each select="*/MT[starts-with(@N, 'Author')]"> 
     <xsl:value-of select="@V"/> 
    </xsl:for-each> 
</xsl:template> 
</xsl:stylesheet> 

当所提供的XML文档应用：

<R N="14" MIME="application/pdf"> 
    <RK>7</RK> 
    <MT N="Abstract" V="Lorem Ipsum is simply dummy text of the printing " /> 
    <MT N="Abstract1" V="and typesetting industry. Lorem Ipsum has been the industry's standard " /> 
    <MT N="Author" V="Bernard Shaw;" /> 
    <MT N="Author1" V="Mark Twain" /> 
    <MT N="Abstract2" V="dummy text ever since the 1500s, when an unknown printer took a galley" /> 
    <LANG>en</LANG> 
</R> 

产生想要的结果：

Abstract: Lorem Ipsum is simply dummy text of the printing and typesetting industry. Lorem Ipsum has been the industry's standard dummy text ever since the 1500s, when an unknown printer took a galley 
Author: Bernard Shaw;Mark Twain 

此外重构：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/"> 
    Abstract: <xsl:text/> 
    <xsl:call-template name="concatAttributes"/> 
    Author: <xsl:text/> 
    <xsl:call-template name="concatAttributes"> 
     <xsl:with-param name="pKeyStartString" select="'Author'"/> 
    </xsl:call-template> 
</xsl:template> 

<xsl:template name="concatAttributes"> 
    <xsl:param name="pKeyAttribName" select="'N'"/> 
    <xsl:param name="pKeyStartString" select="'Abstract'"/> 
    <xsl:param name="pValueAttribName" select="'V'"/> 

    <xsl:for-each select= 
     "*/MT[starts-with(@*[name()=$pKeyAttribName], $pKeyStartString)]"> 
     <xsl:value-of select="@*[name()=$pValueAttribName]"/> 
    </xsl:for-each> 
</xsl:template> 
</xsl:stylesheet> 

第二重构（由OP请求）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="text"/> 
    <xsl:strip-space elements="*"/> 
    <xsl:variable name="vAbstract"> 
     <xsl:apply-templates mode="retrieve" select="//MT"/> 
    </xsl:variable> 
    <xsl:variable name="vAuthors"> 
     <xsl:apply-templates mode="retrieve" select="//MT"> 
      <xsl:with-param name="pKeyStartString" select="'Author'"/> 
     </xsl:apply-templates> 
    </xsl:variable> 

    <xsl:template match="/"> 
    Abstract: <xsl:value-of select="$vAbstract"/> 
    Authors:: <xsl:value-of select="$vAuthors"/> 
    </xsl:template> 

    <xsl:template match="MT" mode="retrieve"> 
     <xsl:param name="pKeyAttribName" select="'N'"/> 
     <xsl:param name="pKeyStartString" select="'Abstract'"/> 
     <xsl:param name="pValueAttribName" select="'V'"/> 
     <xsl:if test="starts-with(@*[name()=$pKeyAttribName], $pKeyStartString)"> 
      <xsl:value-of select="@*[name()=$pValueAttribName]"/> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet> 

EDIT：该OP已请求“的所有处理应于进行模板匹配MT“。虽然在简单情况下可能会发生这种情况（请参阅@ Alejandro的答案），但在匹配MT的单个模板中执行所有处理会打开未知数的巨大差距。例如，可能需要以不同的方式处理其他MT元素，在这种情况下，根本不会完成这样的处理。在更复杂的情况下（例如元素和属性以任何顺序出现，但输出必须排序时 - Abstract1，Abstract2，...，Abstract-N），则必须明确指定排序并且这必须在匹配MT的模板之外。 因此，在一般情况下，仅在模板匹配的模板MT内才能生成所需的输出。

我建议单模板匹配MT是在一个名为模式，它应该在“拉风”中使用 - 调用方显式应用。

Answer 2

<xsl:for-each select="MT[starts-with(@N, 'Abstract')]"> 
    <xsl:if test="position() = 1"> 
     <xsl:value-of select="@N"/>: 
    </xsl:if> 
    <xsl:value-of select="@V"/> 
</xsl:for-each> 

Answer 3

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:key name="kMtByAlphaN" 
      match="MT" 
      use="concat(generate-id(..),'+',translate(@N,'1234567890',''))"/> 
    <xsl:template match="MT[count(.|key('kMtByAlphaN', 
             concat(
              generate-id(..),'+', 
              translate(@N,'1234567890','') 
             ) 
            )[1] 
          ) = 1 
         ]"> 
     <xsl:variable name="vName" 
         select="translate(@N,'1234567890','')"/> 
     <xsl:value-of select="concat($vName,': ')"/> 
     <xsl:apply-templates select="key('kMtByAlphaN', 
              concat(generate-id(..),'+',$vName) 
            )/@V"/> 
     <xsl:text>&#xA;</xsl:text> 
    </xsl:template> 
    <xsl:template match="text()"/> 
</xsl:stylesheet> 

输出：

Abstract: Lorem Ipsum is simply dummy text of the printing and typesetting industry. Lorem Ipsum has been the industry's standard dummy text ever since the 1500s, when an unknown printer took a galley 
Author: Bernard Shaw;Mark Twain 

注意：由@N字母内容和家长生成的ID，因为我希望几个R元素分组。