在Qt Multimedia中拍摄视频快照

Question

是否有可能在Qt Multimedia中拍摄视频快照？怎么样？

Answer 1

这取决于平台，但你也许可以做的是使用QMediaPlayer，通过setVideoOutput设置一个子类的视频表面，并获得来自QVideoFrame在present方法传递的帧数据。然后你必须处理帧格式并映射它们是否不在CPU内存中。

但是，根据您的需要，我会使用ffmpeg/libav从特定位置获取帧。

Answer 2

（文档在这里：http://doc.qt.io/qt-5/qml-qtquick-item.html#grabToImage-method）试试这个

import QtQuick 2.5 
import QtQuick.Window 2.2 
import QtQuick.Controls 1.4 
import QtQuick.Layouts 1.1 
import QtMultimedia 5.0 

Window { 
    id: mainWindow 
    visible: true 
    width: 480 
    height: 800 

    MediaPlayer {  
     id: player 
     source: "file:///location/of/some/video.mp4" 
     autoPlay: false    
    } 

    ColumnLayout { 
     anchors.fill: parent 
     VideoOutput { 
      id: output 
      source: player 
      Layout.fillHeight: true 
      Layout.fillWidth: true     
     } 

     Row { 
      id: buttonsRow 
      height: 100 
      spacing: 20 
      anchors.horizontalCenter: parent.horizontalCenter 
      Layout.margins: 10     

      Button { 
       id: playPauseButton 
       text: player.playbackState === MediaPlayer.PlayingState ? "Pause" : "Play" 
       onClicked: { 
        var playing = player.playbackState === MediaPlayer.PlayingState; 
        playing ? player.pause() : player.play(); 
       } 
      }     
      Button { 
       text: "Snapshot" 
       onClicked: { 
        output.grabToImage(function(image) { 
         console.log("Called...", arguments) 
         image.saveToFile("screen.png"); // save happens here 
        }); 
       } 
      } 
     } 
    } 
}