XSLT：我想基于使用XSLT 1.0

Question

正在尝试使用XSLT 1.0

源XML扁平化基础上的子元素名称的XML元素的子元素的名字拼合XML元素：

<Contact> 
    <ContactPurpose> 
    <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
    </ContactPurpose> 
    <ContactPurpose> 
    <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
    </ContactPurpose> 
</Contact> 

应变换为下面的XML：

<Contact> 
    <ContactPurpose>O</ContactPurpose> 
    <ContactPurpose>Call</ContactPurpose> 
</Contact> 

的逻辑是：

如果子元素名称是“PurposeAsPlainText“目的地THEN 集‘O’为其他

ELSEIF子元素名称是‘PurposeAsEnum’THEN 源值复制到目标

编辑1：我可能会更清楚，因为没有任何解决方案将XML解压缩，请参阅修订的源和目标XML。

编辑2：这是我测试的XML。下面的两个转换解决方案实际上可以在我的原始xml上工作，但不是我使用.NET 4.0 XslCompiledTransform进行测试的修订后的xml。或者我应该提出一个新问题？

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
    <Demographics> 
     <Contact> 
     <ContactPurpose> 
      <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
     </ContactPurpose> 
     <ContactPurpose> 
      <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
     </ContactPurpose> 
     </Contact> 
    </Demographics> 
    </PatientRecord> 
</MyDS> 

Answer 1

这可以在一个简单的和短期的方式来完成（没有明确的条件语句）：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:x="cds_dt" exclude-result-prefixes="x"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="ContactPurpose/x:PurposeAsPlainText/text()">0</xsl:template> 

<xsl:template match="ContactPurpose/*"><xsl:apply-templates/></xsl:template> 
</xsl:stylesheet> 

当施加到下面的XML文档（扩展到encorporate感兴趣这两种情况下）：

<Contact> 
    <ContactPurpose> 
     <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
    </ContactPurpose> 
    <ContactPurpose> 
     <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
    </ContactPurpose> 
</Contact> 

产生想要的，正确的结果：

<Contact> 
    <ContactPurpose>0</ContactPurpose> 
    <ContactPurpose>Call</ContactPurpose> 
</Contact> 

说明：

重写identity rule和适当使用的模板/匹配模式。

更新：该任择议定书已经修改了他的XML文档，这是现在在默认命名空间：

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
     <Demographics> 
      <Contact> 
       <ContactPurpose> 
        <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
       </ContactPurpose> 
       <ContactPurpose> 
        <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
       </ContactPurpose> 
      </Contact> 
     </Demographics> 
    </PatientRecord> 
</MyDS> 

因此，这里是产生想要的结果略微修改后的转换：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:x="cds_dt" xmlns:c="cds" exclude-result-prefixes="c x"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="c:ContactPurpose/x:PurposeAsPlainText/text()">0</xsl:template> 

    <xsl:template match="c:ContactPurpose/*"><xsl:apply-templates/></xsl:template> 
</xsl:stylesheet> 

将此转换应用于新XML文档（最接近的上面）时，新的想要的正确结果是produc编号：

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
     <Demographics> 
     <Contact> 
      <ContactPurpose>0</ContactPurpose> 
      <ContactPurpose>Call</ContactPurpose> 
     </Contact> 
     </Demographics> 
    </PatientRecord> 
</MyDS> 

Answer 2

<?xml version="1.0" encoding="iso-8859-1"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:cds="cds_dt" exclude-result-prefixes="cds"> 
<!-- identity transform - just copy things that don't have a better rule --> 
<xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<!- a rule for what needs changing --> 
<xsl:template match="ContactPurpose[cds:PurposeAsPlainText] "> 
    <ContactPurpose>O</ContactPurpose> 
</xsl:template> 
</xsl:stylesheet> 

Answer 3

更新：修改了答案，以适应变化的XML源文档。

的描述不是很清楚，但这里是我认为你正在试图做的：

<xsl:stylesheet version="1.0" xmlns:cds_dt="cds_dt" xmlns:cds="cds" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<!-- Identity transform --> 
<xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="cds:ContactPurpose"> 
    <xsl:copy> 
     <xsl:choose> 
     <!-- when there is a child element PurposeAsPlainText 
      in the cds_dt namespace: --> 
     <xsl:when test="cds_dt:PurposeAsPlainText">0</xsl:when> 
     <!-- I'm guessing that PurposeAsEnum is also supposed to be 
      in the cds_dt namespace. --> 
     <xsl:otherwise> 
      <xsl:value-of select="cds_dt:PurposeAsEnum" /> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>