在xtext项目中使用xtend生成代码

Question

我正在处理xtext项目，并且我通过.xtext文件生成对象。 我想将新的属性添加到其中一个生成的对象。 我看到http://christiandietrich.wordpress.com/2011/07/22/customizing-xtext-metamodel-inference-using-xtend2/ 下面的代码是在ObjectValue 中生成一个临时变量，但我希望临时是类型MyObject。

如何做？我在哪里可以读到它？

import org.eclipse.emf.codegen.ecore.genmodel.GenModelPackage 
import org.eclipse.emf.common.util.BasicEMap$Entry 
import org.eclipse.emf.ecore.EClass 
import org.eclipse.emf.ecore.EPackage 
import org.eclipse.emf.ecore.EcoreFactory 
import org.eclipse.emf.ecore.EcorePackage 
import org.eclipse.xtext.GeneratedMetamodel 
import org.eclipse.xtext.xtext.ecoreInference.IXtext2EcorePostProcessor 

class CodeGeneratorClass implements IXtext2EcorePostProcessor { 

    override process(GeneratedMetamodel metamodel) { 
     metamodel.EPackage.process 
    } 

    def process(EPackage p) { 
     for (c : p.EClassifiers.filter(typeof(EClass))) { 
      if (c.name == "ObjectValue") { 
       c.handle 
      } 
     } 
    } 

    def handle (EClass c) { 
    val attr = EcoreFactory::eINSTANCE.createEAttribute 
    attr.name = "temp" 
    attr.EType = EcorePackage::eINSTANCE.EString 
    c.EStructuralFeatures += attr 
} 
} 

Answer 1

第一：MyObject必须由EClass或EDataType来描述任一。一个普通的Java对象不会这样做。

如果MyObject是一个EDataType则必须在handle方法添加EAttribute。你handle方法差不多吧，只有EType必须调整：

attr.EType = MyPackage::eINSTANCE.MyObject 

否则：如果MyObject是EClass则必须添加一个EReference而不是EAttribute。这种情况下的handle方法是这样的：

def handleReference(EClass c){ 
    val ref = EcoreFactory::eINSTANCE.createEReference 
    ref.name = "temp" 
    ref.EType = MyPackage::eINSTANCE.MyObject 
    c.EStructuralFeatures += ref 
} 

编辑

为了定义一个新的，最小的EDataType并把它挂到模型下面的代码片段应该工作：

def void process(GeneratedMetamodel it){ 
    // create new dynamic EDataType 
    val dataType = EcoreFactory::eINSTANCE.createEDataType => [ 
     name = 'MyObject' 
     instanceTypeName = 'java.package.with.MyObject' 
    ] 

    // register new EDataType in own model package 
    EPackage.EClassifiers += dataType 

    // attach as EAttribute to appropriate EClasses 
    EPackage.EClassifiers.filter(typeof(EClass)).filter[name == 'ObjectValue'].forEach[ 
     EStructuralFeatures += EcoreFactory::eINSTANCE.createEAttribute => [ 
      name = "temp" 
      EType = dataType 
     ] 
    ] 
}