如何获得薪水高于其部门平均水平的员工的姓名和部门？

Question

我是Hadoop和pig的新手。根据问题我能够深入研究，直到下面的脚本，但我怎么能比较个人的薪水与他的部门的平均工资。以下是写入得到各部门的平均工资脚本

A = LOAD 'Assignment_1_Input.log' USING PigStorage('\t') as (id:int,name:chararray,age:int,salary:int,deptid:int); 
B = GROUP A by deptid; 
STORE B INTO 'Assign1GrpByNew'; 
C = FOREACH B GENERATE group as grpId,AVG(A.salary) as grpAvgSal; 
DUMP C; 

输入文件：

15878 mohan 24  8000 1 
19173 ramya 27  10000 1 
9527 krishna 35  40000 2 
9528 raj  36  60000 2 
16884 ravi 50  70000 2 

期望输出

ramya 1 
raj 2 
ravi 2 

帮我个忙，谢谢

Answer 1

JOIN A和C by deptid，grpId和FILTER where salary> grpAvgSal

A = LOAD 'Assignment_1_Input.log' USING PigStorage('\t') as (id:int,name:chararray,age:int,salary:int,deptid:int); 
B = GROUP A by deptid; 
STORE B INTO 'Assign1GrpByNew'; 
C = FOREACH B GENERATE group as grpId,AVG(A.salary) as grpAvgSal; 

D = JOIN A BY deptid,C BY grpId; 
E = FILTER D BY (A::salary > C::grpAvgSal); 
DUMP E; 

Answer 2

GROUP BY dept_id并计算每个员工记录的平均工资并选择那些工资大于平均值的员工。

段：

inp_data = LOAD 'Assignment_1_Input.log' USING PigStorage('\t') as (id:int,name:chararray,age:int,salary:int,deptid:int); 
inp_data_fmt = FOREACH(GROUP inp_data BY deptid) GENERATE FLATTEN(inp_data), AVG(inp_data.salary) AS avg_salary; 
req_data = FILTER inp_data_fmt BY salary > avg_salary; 
DUMP req_data;