变化选择框状态，而无需调用onclick事件

Question

我不知道，所以当我变化选择框

CheckBox->Checked=false; 

的状态，它调用CheckBoxOnClick事件，如何避免呢？

Answer 1

你可以围绕onClick事件代码的东西，如

if myFlag then 
    begin 
    ...event code... 
    end; 

如果你不希望它被执行，设置myFlag假后的复选框状态的改变将其设置回真正的做。

Answer 2

我希望有一个按钮解决方案，但您可以将当前事件存储在TNotifyEvent var中，然后将Checkbox.OnChecked设置为零，然后将其恢复。

Answer 3

另一种选择是使用中介类这样的改变保护ClicksDisable属性：

type 
    THackCheckBox = class(TCustomCheckBox) 
    end; 

procedure TCheckBox_SetCheckedNoOnClick(_Chk: TCustomCheckBox; _Checked: boolean); 
var 
    Chk: THackCheckBox; 
begin 
    Chk := THackCheckBox(_Chk); 
    Chk.ClicksDisabled := true; 
    try 
    Chk.Checked := _Checked; 
    finally 
    Chk.ClicksDisabled := false; 
    end; 
end; 

Answer 4

CheckBox.State := cbUnchecked;作品在Delphi中，这不火onClickEvent AFAIK

Answer 5

在您可以使用新版本的Delphi类助手添加此功能：

CheckBox.SetCheckedWithoutClick(False); 

通过使用VCL的以下类助手TCheckBox：

TCheckBoxHelper = class helper for TCheckBox 
    procedure SetCheckedWithoutClick(AChecked: Boolean); 
end; 

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean); 
begin 
    ClicksDisabled := True; 
    try 
     Checked := AChecked; 
    finally 
     ClicksDisabled := False; 
    end; 
end; 

只是为了完整性：一个FMX TCheckBox会表现相似（触发OnChange）。您可以使用下面的类帮助解决此：

TCheckBoxHelper = class helper for TCheckBox 
    procedure SetCheckedWithoutClick(AChecked: Boolean); 
end; 

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean); 
var 
    BckEvent: TNotifyEvent; 
begin 
    BckEvent := OnChange; 
    OnChange := nil; 
    try 
     IsChecked := AChecked; 
    finally 
     OnChange := BckEvent; 
    end; 
end; 

免责声明：谢谢，dummzeuch了原来的想法。注意班级助手的常见提示。

Answer 6

试试这个方法：

Checkbox.OnClick := nil; 
try 
    Checkbox.Checked := yourFlag; 
finally 
    Checkbox.OnClick := CheckboxClick; 
end; 

Answer 7

简单的办法就是把你的onclick代码onmouseup事件;