从祖先的祖先继承方法

Question

我正在研究从商业组件套件派生的组件，并且遇到了一个我从未考虑过的挑战。请看下面的代码片段：

TMyClass = class 
protected 
    procedure SomeMethod; virtual; 
end; 

TMyClass1 = class(TMyClass) 
protected 
    procedure SomeMethod; override; 
end; 

TMyMode = (mmOne, mmTwo); 
TMyClass2 = class(TMyClass1) 
private 
    FMode: TMyMode; 
protected 
    procedure SomeMethod; override; 
public 
    property Mode: TMyMode read FMode write FMode; 
end; 

... 

procedure TMyClass2.SomeMethod; 
begin 
    if FMode = mmOne then inherited SomeMethod 
        else inherited TMyClass.SomeMethod; 
end; 

所以，如果模式= mmOne然后我继承是正常的，但如果它是mmTwo，我还是想继承我的祖先的祖先的代码，但是不知道是在祖先介绍。我已经尝试了上述，但没有成功，因为我以前从未遇到过这种情况，所以我认为这是不可能的。任何接受者？

Answer 1

你可以用类佣工这样做：

type 
    TA = class 
    public 
    procedure X; virtual; 
    end; 

    TB = class(TA) 
    public 
    procedure X; override; 
    end; 

    TA_Helper = class helper for TA 
    procedure A_X; 
    end; 

    TC = class(TB) 
    public 
    procedure X; override; 
    end; 

procedure TA.X; 
begin 
    // ... 
end; 

procedure TB.X; 
begin 
    // ... 
end; 

procedure TA_Helper.A_X; 
begin 
    inherited X; // TA.X 
end; 

procedure TC.X; 
begin 
    A_X; 
    inherited X; // TB.X 
end; 

我觉得在D2006中存在类的帮手，但如果他们不这样做，你也可以使用一劈到一样的效果：

// ... 
    TA_Helper = class(TA) 
    procedure A_X; 
    end; 
// ... 
procedure TC.X; 
begin 
    TA_Helper(Self).A_X; 
    inherited X; // TB.X 
end; 

Answer 2

有没有类助手或其他方法（如在@ hvd答案）这个任务的另一种解决方案。你可以得到基类方法的代码地址和self数据指针调用它：
更新的代码，没有RTTI

unit Unit4; 

interface 
type 
    TA = class(TObject) 
     protected 
     procedure Test(); virtual; 
    end; 

    TB = class(TA) 
     protected 
     procedure Test(); override; 
    end; 

    TC = class(TB) 
     public 
     procedure Test(); override; 
    end; 

implementation 

procedure TA.Test; 
begin 
    writeln('TA.Test()'); 
end; 

procedure TB.Test; 
begin 
    writeln('TB.Test'); 
end; 

procedure TC.Test; 
var TATest : procedure of object; 
begin 
    writeln('TC.Test();'); 
    writeln('call inherited TB: '); 
    inherited Test(); 


    writeln('call inherited TA:'); 
    TMethod(TATest).Data := self; 
    TMethod(TATest).Code := @TA.Test; 
    TATest(); 
end; 
end.